[编程交流] 选择端点

 
(setq Pt1 (getpoint "\n pick point"))
   (if Pt1  
         (progn
                    ;do some stuff 
          )        
        (alert "Nothing Picked.")  
       )

(if (and (setq Pt1 (getpoint "\n pick point"))
        (setq Pt1 (osnap Pt1 "_ENDP"))
   )
 (alert (vl-princ-to-string Pt1))
 ;; else
 (alert "Ooops")
)

(setq tp1 (entsel "\nSelect left side inner wall near end : "))
(setq tpp1 (entget (car tp1)))
(setq pt1 (cdr (assoc 10 tpp1)))      
(setq pt2 (cdr (assoc 11 tpp1)))      
(setq pt3 (cadr tp1))
 (setq d1 (distance pt1 pt3))
(setq d2 (distance pt2 pt3))
 (if (> d1 d2)
 (progn 
  (setq temp pt1)
  (setq pt1 pt2)
  (setq pt2 temp)
 )
 )

(vl-load-com)
(if (setq Lin (ssget "_+.:S" '((0 . "LINE"))))
 (progn
   (setq Ent (ssname Lin 0)
  Obj (vlax-ename->vla-object Ent)
  End (vlax-get obj 'endpoint)
  )
   )
 (alert "Nothing's Picked")
 )

(Defun Get_End_Point (/ oldosmod flag point)
 (vl-load-com)
 (setq        oldosmod (getvar 'OSMODE)
flag         T
 )
 (vl-catch-all-apply
   (function
     (lambda ()
(setvar 'OSMODE 1)
(while flag
  (setq        point (getpoint "\nSelect an Endpoint <Exit>:")
  )
  (cond
    ((not point)
     (setq flag        nil
           point nil
     )
    )
    ((ssget point) (setq flag nil))
    (t (princ "\n Miss"))
  )
)
     )
   )
 )
 (setvar 'OSMODE oldosmod)
 point
)

(defun foo (/ e)
 (if (setq e (entsel))
   (osnap (cadr e) "_ENDP")
 )
)

(defun AT:ClosestPoint (ep / _next _dist ep el lst)
 ;; Return closest point to selected entity
 ;; ep - entity and point list
 ;; Alan J. Thompson, 09.14.10
 (defun _next (e / p)
   (if (and (setq e (entnext e)) (setq p (cdr (assoc 10 (entget e)))))
     (cons p (_next e))
   )
 )
 (defun _dist (a b) (distance (list (car a) (cadr a)) (list (car b) (cadr b))))
 (if
   (and (vl-consp ep)
        (eq (type (car ep)) 'ENAME)
        (or (eq 1 (getvar 'worlducs)) (setq ep (list (car ep) (trans (cadr ep) 1 0))))
        (cond
          ((vl-position (cdr (assoc 0 (setq el (entget (car ep))))) '("ARC" "LINE" "SPLINE"))
           (setq lst (list (vlax-curve-getStartPoint (car ep)) (vlax-curve-getEndPoint (car ep))))
          )
          ((eq (cdr (assoc 0 el)) "LWPOLYLINE")
           (foreach p el (and (eq (car p) 10) (setq lst (cons (cdr p) lst))))
           lst
          )
          ((eq (cdr (assoc 0 el)) "POLYLINE") (setq lst (_next (car ep))))
        )
   )
    (car (vl-sort lst (function (lambda (a b) (< (_dist a (cadr ep)) (_dist b (cadr ep)))))))
 )
)

(defun c:Test (/ p)
 (if (setq p (AT:ClosestPoint (entsel "\nSelect curve: ")))
   (entmake (list '(0 . "CIRCLE") (cons 10 p) '(40 . 10.)))
 )
 (princ)
)