我如何使用entmakex来

Tharwat · 发表于 2022-7-6 11:09:54

对。你说得对。

但我不想使用explode命令将它们转换为文本。

它来了。


(setq x '10.0
     y '20.0
     z '30.0
     )
(setq pt (getpoint "\n Specify text location :"))
(entmakex (list (cons 0 "MTEXT")
        (cons 100 "AcDbEntity")
                (cons 100 "AcDbMText")
                (cons 10  pt)
                (cons 40 (getvar 'textsize))
                (cons 1  (strcat (rtos x 2 1)"\n"(rtos y 2 1)"\n"(rtos z 2 1)))))

Lee Mac · 发表于 2022-7-6 11:11:10

也许这可以作为一个例子：

copy


(defun c:mpt ( / MText norm pt )
 ;; © Lee Mac 2010
 (defun MText ( pt val norm )
   (entmakex
     (list
       (cons 0 "MTEXT")
       (cons 100 "AcDbEntity")
       (cons 100 "AcDbMText")
       (cons 10 pt)
       (cons 11 (getvar 'UCSXDIR))
       (cons 1  val)
       (cons 210 norm)
     )
   )
 )
 (setq norm (trans '(0. 0. 1.) 1 0 t))
 (terpri)
 (while (setq pt (getpoint "\rSpecify Point: "))
   (setq pt (trans pt 1 0))
   
   (MText pt
     (apply 'strcat
       (mapcar 'strcat '("X = " "\nY = " "\nZ = ") (mapcar 'rtos pt))
     )
     norm
   )
 )
 (princ)
)

Lt Dan's l · 发表于 2022-7-6 11:15:30

很抱歉。。。我不知道我为什么这么想

Tharwat · 发表于 2022-7-6 11:17:42

真是难以置信。

第一它表现得很好。

第二今天我一直在想做一个常规动作，就像你在上一篇文章中做的那样。我感到无言以对

所以你今晚为我做了二合一。

非常感谢你。

塔瓦特

Tharwat · 发表于 2022-7-6 11:22:53

没问题。我非常感谢你的帮助。

非常感谢。

塔瓦特

Lee Mac · 发表于 2022-7-6 11:27:40

不客气，塔瓦，我很高兴你能发现它很有用

Tharwat · 发表于 2022-7-6 11:30:09

当我用Vlide编辑器检查它时，我才意识到。它返回，因为它在检查的响应中很清楚。。。

copy


; warning: local variable used as function: MTEXT

Lee Mac · 发表于 2022-7-6 11:32:16

我不担心这些-它不喜欢局部函数。

[编程交流] 我如何使用entmakex来

发表回复

精选推荐