[编程交流] 匹配Dimstyle和layer

(defun c:test (/ e)
 (and (setq e (car (entsel "\nSelect Dimension: ")))
      (or (eq "DIMENSION" (cdr (assoc 0 (setq e (entget e)))))
          (alert "Invalid object!")
      )
      (setvar 'clayer (cdr (assoc 8 e)))
      (command "_.-dimstyle" "_restore" (cdr (assoc 3 e)))
 )
 (princ)
)

(defun c:DimMatch ( / doc obj )
 (vl-load-com)
 (defun Itemp ( coll item )
   (if
     (not
       (vl-catch-all-error-p
         (setq item
           (vl-catch-all-apply
             (function vla-item) (list coll item)
           )
         )
       )
     )
     item
   )
 )
 (if
   (progn
     (vla-GetEntity
       (vla-get-Utility
         (setq doc
           (vla-get-ActiveDocument
             (vlax-get-Acad-Object)
           )
         )
       )
       'obj
       "\nSelect Dimension: "
     )
     (and obj
       (wcmatch
         (strcase
           (vla-get-ObjectName obj)
         )
         "*DIMENSION*,*LEADER"
       )
     )
   )
   (mapcar
     (function
       (lambda ( Information )
         (apply
           (function
             (lambda ( Dest Collection Source )
               (vlax-put-property doc Dest
                 (itemp Collection
                   (vlax-get-property obj Source)
                 )
               )
             )
           )
           Information
         )
       )
     )
     (list
       (list (quote ActiveLayer)   (vla-get-layers    doc) (quote Layer))
       (list (quote ActiveDimstyle)(vla-get-Dimstyles doc) (quote StyleName))
     )
   )
 )
 (princ)
)

 ^C^C(or c:Match (load "C:/acad/match.lsp" nil));MATCH;