查找零长度PLine。。

Hangman · 发表于 2022-7-6 11:19:11

嘿伙计们，
你会如何过滤掉并找到一条零长度的pline？？

我有几张从Microstation转换过来的图纸，当我运行Eduard的“FLAT.lsp”来展平这个东西时，我得到了一个约25.563245e27的零长度PLine。。。距离很远，我的画在黑屏上变成了两个点。

我想在末尾添加一段代码，简单地过滤掉并找到一条愚蠢的零长度pline，然后删除它。

任何帮助都将不胜感激。谢谢

Lee Mac · 发表于 2022-7-6 11:38:38

也许是类似的？

copy


(defun c:FindZeroLengthPlines ( / i ss e zro )
 (if (setq i -1 zro (ssadd) ss (ssget "_X" '((0 . "LWPOLYLINE"))))
   (while (setq e (ssname ss (setq i (1+ i))))
     (and (equal 0.0 (vlax-curve-getDistatParam e
                       (vlax-curve-getEndParam e)) 1e-14)
          (ssadd e zro))))
 (sssetfirst nil zro)
 (princ))

alanjt · 发表于 2022-7-6 11:49:00

直到我编写了这个代码，我才想到QSelect，我注意到李已经做了一个，但由于我花了时间，我还是会发布它。

copy

(defun c:SZP (/ ss)
 ;; Select Zero Length LWPolylines
 ;; Alan J. Thompson, 04.26.10
 (if (setq ss (ssget "_X" '((0 . "LWPOLYLINE") (90 . 2))))
   ((lambda (i ss2)
      (while (setq e (ssname ss (setq i (1+ i))))
        (or (> (vlax-curve-GetDistAtParam e (vlax-curve-GetEndParam e)) 0.)
            (ssadd e ss2)
        )
      )
      (and (sssetfirst nil ss2)
           (princ (strcat "\n" (itoa (sslength ss2)) " zero length LWPolyline(s) selected."))
      )
    )
     -1
     (ssadd)
   )
 )
 (princ)
)