按名称选择块

klpocska · 发表于 2022-7-6 11:35:35

如何使用VBA在模型空间中按（块）名称选择块？

alanjt · 发表于 2022-7-6 11:45:53

http://www.cadtutor.net/forum/showthread.php?t=25142

klpocska · 发表于 2022-7-6 12:00:11

谢谢，

如何按块名创建Acad选择集？

SEANT · 发表于 2022-7-6 12:06:17

创建一个包含特定名称的所有块引用的过滤选择集的过程如下所示：

copy

Sub GetNamedInserts()
  Dim entbref As AcadBlockReference
  Dim TempObjSS As AcadSelectionSet
  Dim intCode(2) As Integer
  Dim varData(2) As Variant
  Dim strName As String
  
     strName = ThisDrawing.Utility.GetString(0, "Enter Block name to select: ")
     SSInit
     Set TempObjSS = ThisDrawing.SelectionSets.Add("TempSSet")
     intCode(0) = 0: varData(0) = "Insert"
     intCode(1) = 67: varData(1) = 0
     intCode(2) = 2: varData(2) = strName
     TempObjSS.Select acSelectionSetAll, , , intCode, varData
     MsgBox "There are " & TempObjSS.Count & " inserts referencing " & strName & " in Modelspace"
End Sub
Sub SSInit()
Dim SSS As AcadSelectionSets
Dim SS As AcadSelectionSet
  Set SSS = ThisDrawing.SelectionSets
     If SSS.Count > 0 Then
        For Each SS In SSS
           If SS.Name = "TempSSet" Then
              SS.Delete
              Exit For
           End If
        Next
     End If
End Sub