乐筑天下

搜索
欢迎各位开发者和用户入驻本平台 ☆ ☆ ☆ 尊重版权，从我做起，拒绝盗版，拒绝倒卖 ☆ ☆ ☆ 签到、发布资源、邀请好友注册，可以获得银币 ☆ ☆ ☆ 请注意保管好自己的密码，避免账户资金被盗
查看： 19|回复： 19

[编程交流] 用s旋转所有属性

[复制链接]
The Buzzard

32

主题

1166

帖子

1146

银币

初露锋芒

Rank: 3Rank: 3Rank: 3

铜币
159
发表于 2022-7-6 11:45:29 | 显示全部楼层 |阅读模式
2009年7月28日
以下是完整的修订代码。
此代码将提示输入旋转角度。
代码也有错误捕捉。
要将此程序用于您自己的区块
属性指以红色突出显示的代码部分。
您可以在代码中的此处更改属性标记
与您自己的属性标记一起使用。
请参阅下面的附加Line_扩展。测试程序的图纸。
 
此代码的函数语法：AVR
Line_扩展。图纸
AVR。拉链
回复

使用道具 举报

The Buzzard

32

主题

1166

帖子

1146

银币

初露锋芒

Rank: 3Rank: 3Rank: 3

铜币
159
发表于 2022-7-6 11:49:04 | 显示全部楼层
 
 
无论如何，谢谢你，我知道了！
 
  1. (defun C:TVR ()
  2.  (setq BNAM "8-WAY")
  3.  (setq BLOCROT (ssget "x" (list (cons 0 "INSERT")(cons 2 BNAM)(cons 66 1))))
  4.  (if
  5.    (/= BLOCROT nil)
  6.    (progn
  7.      (setq INDEX 0)
  8.      (repeat
  9.        (sslength BLOCROT)
  10.        (setq ENAME (ssname BLOCROT INDEX))
  11.        (setq ELIST (entget ENAME))
  12.        (while
  13.          (/= (cdr (assoc 0 ELIST)) "SEQEND")
  14.          (setq ELIST (entget ENAME))
  15.          (if 
  16.            (= "TAP-VAL" (cdr (assoc 2 ELIST)))
  17.            (progn
  18.              (entmod
  19.                (subst
  20.                  (cons 50 0.0)
  21.                  (assoc 50 ELIST) ELIST
  22.                )
  23.              )
  24.              (entupd ENAME)
  25.            )
  26.          )
  27.          (setq ENAME (entnext ENAME))
  28.        )
  29.        (setq INDEX (1+ INDEX))
  30.      )
  31.    )
  32.    (ALERT (strcat "\nThe block "BNAM" was not found."))
  33.  )
  34.  (princ)
  35. )
回复

使用道具 举报

Freerefill

20

主题

344

帖子

325

银币

初露锋芒

Rank: 3Rank: 3Rank: 3

铜币
100
发表于 2022-7-6 11:53:14 | 显示全部楼层
哇！我写了一些东西来做你想做的事情，有趣的是，我现在正在使用它
 
不确定这是否完全解决了问题，但这是我的函数：
 
  1. (defun c:cr( / ss obj)
  2.  (vl-load-com)
  3.  (if (ssget "X" (list (cons 2 "IDI-SECU-CAMR")))
  4.    (progn
  5.      (vlax-for obj (setq ss (vla-get-activeselectionset (vla-get-activedocument (vlax-get-acad-object))))
  6.    (if (= (vla-get-HasAttributes obj) :vlax-true)
  7.      (foreach attVar (vlax-invoke obj 'GetAttributes)
  8.        (if (not (= (vla-get-TagString attVar) "NUM"))
  9.          (vla-put-Rotation attVar 0)))))
  10.      (vla-delete ss)))
  11.  (princ)
  12.  )

 
非常简单：获取具有特定名称的所有块，然后遍历块的每个属性，看看哪个属性标记为“NUM”，并将旋转设置为0（vla put旋转部分）。我写这篇文章是因为我有很多具有各种旋转的块，我想把所有这些块的属性放回0度旋转，以便于可读性。
 
希望能有所帮助。^。^
回复

使用道具 举报

The Buzzard

32

主题

1166

帖子

1146

银币

初露锋芒

Rank: 3Rank: 3Rank: 3

铜币
159
发表于 2022-7-6 11:55:29 | 显示全部楼层
 
谢谢你，
 
但在上一篇帖子中，我在最后一分钟才弄明白。我很欣赏代码，但我只是在寻找一些方向。我只需要让代码正常工作。我想学习这些东西，而不是依赖别人为我做。相信我，当我告诉你的努力和代码是非常感谢。我知道我很快就想出来了，但你只是在那些时候，你的大脑似乎被洗掉了。
 
 
谢谢
秃鹰
回复

使用道具 举报

Lee Mac

114

主题

1万

帖子

1万

银币

中流砥柱

Rank: 25

铜币
543
发表于 2022-7-6 11:58:35 | 显示全部楼层
另一种快速方法：
 
  2. ;; ============[ AttRot.lsp ]===============
  3. ;;
  4. ;;  FUNCTION:
  5. ;;  Will move Multiple Attribute Tags
  6. ;;
  7. ;;  SYNTAX: ATTROT
  8. ;;
  9. ;;  AUTHOR:
  10. ;;  Copyright (c) 2009, Lee McDonnell
  11. ;;  (Contact Lee Mac, CADTutor.net)
  12. ;;
  13. ;;  VERSION:
  14. ;;  1.0  ~  02.07.2009
  15. ;;
  16. ;; =========================================
  18. (defun c:AttRot (/ *error* lklst ent Blk
  19.                   Obj bNme ss bPt ObjLst
  20.                   iPt gr dat cAng)
  21.  
  22.  (vl-load-com)
  24.  (defun *error* (msg)
  25.    (vla-EndUndoMark
  26.      (vla-get-ActiveDocument
  27.        (vlax-get-acad-object)))
  28.    (if lklst
  29.      (foreach l lklst
  30.        (vla-put-lock
  31.          (car l) (cdr l))))
  32.    (if (not
  33.          (wcmatch
  34.            (strcase msg)
  35.              "*BREAK,*CANCEL*,*EXIT*"))
  36.      (princ
  37.        (strcat "\n<< Error: " msg " >>")))
  38.    (redraw)
  39.    (princ))
  40.            
  42.  (vlax-for l
  43.    (vla-get-layers
  44.      (vla-get-ActiveDocument
  45.        (vlax-get-acad-object)))
  46.    (setq lklst
  47.      (cons
  48.        (cons l
  49.          (vla-get-lock l)) lklst))
  50.    (vla-put-lock l :vlax-false))
  52.  (while
  53.    (progn
  54.      (setq ent
  55.        (car (nentsel "\nSelect Attribute: ")))
  56.      (cond
  57.        ((eq 'ENAME (type ent))
  58.         (if
  59.           (not
  60.             (eq "ATTRIB"
  61.                 (cdr (assoc 0 (entget ent)))))
  62.           (princ "\n** Object is not an Attribute **")
  63.           nil))
  64.        (t (princ "\n** Nothing Selected **")))))
  66.  (setq Blk
  67.    (vla-ObjectIdtoObject
  68.      (vla-get-ActiveDocument
  69.        (vlax-get-acad-object))
  70.      (vla-get-OwnerId
  71.        (setq Obj
  72.          (vlax-ename->vla-object ent)))))
  74.  (setq bNme
  75.    (if (vlax-property-available-p Blk 'EffectiveName)
  76.      (vla-get-EffectiveName Blk)
  77.        (vla-get-Name Blk)))
  79.  (setq ss
  80.    (ssget "_X" (list (cons 0 "INSERT")
  81.                        (cons 2 bNme)
  82.                          (cons 66 1))))
  84.  (vla-StartUndoMark
  85.    (vla-get-ActiveDocument
  86.      (vlax-get-acad-object)))
  88.  (setq ObjLst
  89.    (vl-remove-if-not
  90.      (function
  91.        (lambda (x)
  92.          (eq (vla-get-TagString x)
  93.                (vla-get-TagString Obj))))
  94.      (apply 'append
  95.        (mapcar 'asmi-GetAttributes
  96.          (mapcar 'vlax-ename->vla-object
  97.            (mapcar 'cadr (ssnamex ss)))))))
  99.  (setq iPt
  100.    (vlax-safearray->list
  101.      (vlax-variant-value
  102.        (vla-get-TextAlignmentPoint Obj))))        
  104.  (while
  105.    (progn
  106.      (setq gr (grread t 15 0) dat (cadr gr))
  107.      (cond
  108.        ((and (eq 5 (car gr)) (listp dat))
  109.         (redraw)
  110.         (setq cAng
  111.           (angle
  112.             (vlax-safearray->list
  113.               (vlax-variant-value
  114.                 (vla-get-TextAlignmentPoint Obj))) dat))
  115.         (mapcar
  116.           (function
  117.             (lambda (x)
  118.               (vla-put-rotation x cAng))) ObjLst)
  119.         (grvecs (list -6 iPt dat)) t) ; Keep in Loop
  120.        ((or (eq 25 (car gr)) ; Right Click
  121.             (eq 3 (car gr)) ; Left Click
  122.             (and
  123.               (eq 2 (car gr))
  124.               (vl-position dat '(13 32)))) ; Enter Space
  125.         nil) ; Exit Loop
  126.        )))       
  127.         
  129.  (vla-EndUndoMark
  130.    (vla-get-ActiveDocument
  131.      (vlax-get-acad-object)))
  132.  
  133.  (foreach l lklst
  134.    (vla-put-lock
  135.      (car l) (cdr l)))
  137.  (redraw)
  138.  (princ))
  140. ;; ASMI
  141. (defun asmi-GetAttributes (Block / atArr caArr)
  142.   (append
  143.     (if
  144.       (not
  145.         (vl-catch-all-error-p
  146.           (setq atArr
  147.             (vl-catch-all-apply
  148.               'vlax-safearray->list
  149.             (list
  150.               (vlax-variant-value
  151.                 (vla-GetAttributes Block)))))))
  152.           atArr)
  153.     (if
  154.       (not
  155.         (vl-catch-all-error-p
  156.           (setq caArr
  157.             (vl-catch-all-apply
  158.               'vlax-safearray->list
  159.             (list
  160.               (vlax-variant-value
  161.                 (vla-GetConstantAttributes Block)))))))
  162.             caArr)))  
回复

使用道具 举报

The Buzzard

32

主题

1166

帖子

1146

银币

初露锋芒

Rank: 3Rank: 3Rank: 3

铜币
159
发表于 2022-7-6 12:01:58 | 显示全部楼层
 
谢谢李，
 
我的大脑在最后一分钟开始跳动。见帖子2。
非常感谢，但正如你们所知，我不希望代码为我完成。我需要独立解决这个问题。在右边指我
方向就足够了。
 
非常感谢。
秃鹰
回复

使用道具 举报

Lee Mac

114

主题

1万

帖子

1万

银币

中流砥柱

Rank: 25

铜币
543
发表于 2022-7-6 12:05:02 | 显示全部楼层
 
好的，但只是踢-这一个将让你进入角度也
 
  2. ;; ============[ AttRot.lsp ]===============
  3. ;;
  4. ;;  FUNCTION:
  5. ;;  Will move Multiple Attribute Tags
  6. ;;
  7. ;;  SYNTAX: ATTROT
  8. ;;
  9. ;;  AUTHOR:
  10. ;;  Copyright (c) 2009, Lee McDonnell
  11. ;;  (Contact Lee Mac, CADTutor.net)
  12. ;;
  13. ;;  VERSION:
  14. ;;  1.0  ~  02.07.2009
  15. ;;  2.0  ~  02.07.2009
  16. ;;
  17. ;; =========================================
  19. (defun c:AttRot (/ *error* lklst ent Blk
  20.                   Obj bNme ss bPt ObjLst
  21.                   iPt gr dat cAng vl ov str)
  22.  
  23.  (vl-load-com)
  25.  (defun *error* (msg)
  26.    (vla-EndUndoMark
  27.      (vla-get-ActiveDocument
  28.        (vlax-get-acad-object)))
  29.    (if ov (mapcar 'setvar vl ov))
  30.    (if lklst
  31.      (foreach l lklst
  32.        (vla-put-lock
  33.          (car l) (cdr l))))
  34.    (if (not
  35.          (wcmatch
  36.            (strcase msg)
  37.              "*BREAK,*CANCEL*,*EXIT*"))
  38.      (princ
  39.        (strcat "\n<< Error: " msg " >>")))
  40.    (redraw)
  41.    (princ))
  43.  (setq vl '("MODEMACRO")
  44.        ov (mapcar 'getvar vl))           
  46.  (vlax-for l
  47.    (vla-get-layers
  48.      (vla-get-ActiveDocument
  49.        (vlax-get-acad-object)))
  50.    (setq lklst
  51.      (cons
  52.        (cons l
  53.          (vla-get-lock l)) lklst))
  54.    (vla-put-lock l :vlax-false))
  56.  (while
  57.    (progn
  58.      (setq ent
  59.        (car (nentsel "\nSelect Attribute: ")))
  60.      (cond
  61.        ((eq 'ENAME (type ent))
  62.         (if
  63.           (not
  64.             (eq "ATTRIB"
  65.                 (cdr (assoc 0 (entget ent)))))
  66.           (princ "\n** Object is not an Attribute **")
  67.           nil))
  68.        (t (princ "\n** Nothing Selected **")))))
  70.  (setq Blk
  71.    (vla-ObjectIdtoObject
  72.      (vla-get-ActiveDocument
  73.        (vlax-get-acad-object))
  74.      (vla-get-OwnerId
  75.        (setq Obj
  76.          (vlax-ename->vla-object ent)))))
  78.  (setq bNme
  79.    (if (vlax-property-available-p Blk 'EffectiveName)
  80.      (vla-get-EffectiveName Blk)
  81.        (vla-get-Name Blk)))
  83.  (setq ss
  84.    (ssget "_X" (list (cons 0 "INSERT")
  85.                        (cons 2 bNme)
  86.                          (cons 66 1))))
  88.  (vla-StartUndoMark
  89.    (vla-get-ActiveDocument
  90.      (vlax-get-acad-object)))
  92.  (setq ObjLst
  93.    (vl-remove-if-not
  94.      (function
  95.        (lambda (x)
  96.          (eq (vla-get-TagString x)
  97.                (vla-get-TagString Obj))))
  98.      (apply 'append
  99.        (mapcar 'asmi-GetAttributes
  100.          (mapcar 'vlax-ename->vla-object
  101.            (mapcar 'cadr (ssnamex ss)))))))
  103.  (setq iPt
  104.    (vlax-safearray->list
  105.      (vlax-variant-value
  106.        (vla-get-TextAlignmentPoint Obj))) str "")       
  108.  (while
  109.    (progn
  110.      (setq gr (grread t 15 0) dat (cadr gr))
  111.      (setvar "MODEMACRO"
  112.        (strcat "Rotation: "
  113.          (rtos (rtd (vla-get-Rotation Obj)) 2 2) (chr 186)))
  114.      (cond
  115.        ((and (eq 5 (car gr)) (listp dat))
  116.         (redraw)
  117.         (setq cAng
  118.           (angle
  119.             (vlax-safearray->list
  120.               (vlax-variant-value
  121.                 (vla-get-TextAlignmentPoint Obj))) dat))
  122.         (mapcar
  123.           (function
  124.             (lambda (x)
  125.               (vla-put-rotation x cAng))) ObjLst)
  126.         (grvecs (list -6 iPt dat)) t) ; Keep in Loop
  127.        ((eq 2 (car gr))
  128.         (cond ((or (eq 46 dat) (<= 48 dat 57)) ; numbers or dp.
  129.                (princ (chr dat))
  130.                (setq str (strcat str (chr dat))))
  131.               ((eq 8 dat) ; BackSpace
  132.                (princ (strcat (chr  (chr 32) (chr ))
  133.                (setq str (substr str 1 (1- (strlen str)))))
  134.               ((vl-position dat '(32 13)) ; Enter Space
  135.                (if (setq cAng (distof str))
  136.                  (not ; Exit Loop
  137.                    (mapcar
  138.                      (function
  139.                        (lambda (x)
  140.                          (vla-put-rotation x (dtr cAng)))) Objlst))
  141.                  nil)) ; Exit Loop
  142.               (t t))) ; Keep in Loop
  143.        ((or (eq 25 (car gr)) ; Right Click
  144.             (eq 3 (car gr))) ; Left Click
  145.         nil) ; Exit Loop
  146.        (t t)))) ; Keep in Loop
  147.  
  148.  (vla-EndUndoMark
  149.    (vla-get-ActiveDocument
  150.      (vlax-get-acad-object)))
  151.  
  152.  (foreach l lklst
  153.    (vla-put-lock
  154.      (car l) (cdr l)))
  156.  (mapcar 'setvar vl ov)
  157.  (redraw)
  158.  (princ))
  160. (defun rtd (x)
  161.  (* 180. (/ x pi)))
  163. (defun dtr (x)
  164.  (* pi (/ x 180.)))
  166. ;; ASMI
  167. (defun asmi-GetAttributes (Block / atArr caArr)
  168.   (append
  169.     (if
  170.       (not
  171.         (vl-catch-all-error-p
  172.           (setq atArr
  173.             (vl-catch-all-apply
  174.               'vlax-safearray->list
  175.             (list
  176.               (vlax-variant-value
  177.                 (vla-GetAttributes Block)))))))
  178.           atArr)
  179.     (if
  180.       (not
  181.         (vl-catch-all-error-p
  182.           (setq caArr
  183.             (vl-catch-all-apply
  184.               'vlax-safearray->list
  185.             (list
  186.               (vlax-variant-value
  187.                 (vla-GetConstantAttributes Block)))))))
  188.             caArr)))  
回复

使用道具 举报

The Buzzard

32

主题

1166

帖子

1146

银币

初露锋芒

Rank: 3Rank: 3Rank: 3

铜币
159
发表于 2022-7-6 12:09:49 | 显示全部楼层
 
这很新颖，但我只需要将角度设置为零，无论块的角度是什么。稍后我可能会以几种不同的方式使用此例程。至于现在，我很高兴我自己通过了这一关。我可能会将其添加到我喜欢创建的那些块库程序中。
我会及时到达VL，但只有在我先掌握香草之后。
 
谢谢
回复

使用道具 举报

Lee Mac

114

主题

1万

帖子

1万

银币

中流砥柱

Rank: 25

铜币
543
发表于 2022-7-6 12:13:27 | 显示全部楼层
 
我完全理解，这启发了我创建某种属性套件。。。也许以后再来
回复

使用道具 举报

The Buzzard

32

主题

1166

帖子

1146

银币

初露锋芒

Rank: 3Rank: 3Rank: 3

铜币
159
发表于 2022-7-6 12:14:19 | 显示全部楼层
 
听起来很棒。我不得不注意到，属性操作和值编辑是经常提到的非常流行的任务。我相信你会得到很多点击这些节目，因为他们总是在需求。
 
期待着，李，
谢谢
秃鹰
回复

使用道具 举报

12下一页
返回列表 发帖

发表回复

高级模式
B Color Image Link Quote Code Smilies
您需要登录后才可以回帖 登录 | 立即注册

本版积分规则

精选推荐

  • 微信公众平台

  • 扫描访问手机版

  • 点击图片下载手机App

QQ|关于我们|小黑屋|乐筑天下 繁体中文

GMT+8, 2025-3-5 10:57 , Processed in 0.816674 second(s), 72 queries .

© 2020-2025 乐筑天下

联系客服 关注微信 帮助中心 下载APP 返回顶部 返回列表