[编程交流] 这个Lisp程序怎么了？

(defun c:MMNT ()
(vl-load-com)
(if (and (setq ent (car (entsel "\nSelect Object: ")))
(setq pt (getpoint "\nPick a Point: ")))
(progn
(setq obj (vlax-ename->vla-object ent))
(if (vlax-property-available-p obj 'momentOfInertia)
(progn ; SUBPROGN
(setq var (vla-get-MomentOfInertia obj)
     sa (vlax-variant-value var)
     lst (vlax-safearray->list sa)
     MNT (strcat (rtos (car lst) 2 4) " "(rtos (cadr lst) 2 4 ))
         )
(entmakex (list (cons 0 "TEXT")
(cons 10 pt)
(cons 40 (getvar "TEXTSIZE"))
(cons 1 MNT)
) ; end LIST
) ; end entmakex
) ; end SUBPROGN
(princ "\n** Invalid Object Selected **")
) ;END IF
) ; END PROGN
) ; END IF
(princ)
) 

(vlax-safearray->list 
  (vlax-variant-value 
     (vla-get-MomentOfInertia obj)
  )
) 
;;;will return the value in list form. 
;;;Then you can format this as desired.

(vlax-get obj 'MomentofInteria)

(defun c:MMNT  (/ ent pt obj lst MNT)
 (vl-load-com)
 (if (and (setq ent (car (entsel "\nSelect Object: ")))
          (setq pt  (getpoint "\nPick a Point: ")))
   (progn
     (setq obj (vlax-ename->vla-object ent))
     (if (vlax-property-available-p obj 'MomentOfInertia)
       (progn 
         (setq lst (vlax-get obj 'MomentofInertia)
               MNT (strcat (rtos (car lst) 2 4) " " (rtos (cadr lst) 2 4)))
         
         (entmakex (list (cons 0 "TEXT")
                         (cons 10 pt)
                         (cons 40 (getvar "TEXTSIZE"))
                         (cons 1 MNT))))
       
       (princ "\n** Invalid Object Selected **"))))
   
 (princ))