[编程交流] 多段线再生

(defun C:exd (/ *error* vl ov ss) ;; Localise Variables!
 ;; Error Handler to Reset Sys Vars in case User hits Esc!
 
 (defun *error* (msg)
   (and ov (mapcar 'setvar vl ov))
   (or (wcmatch (strcase msg) "*BREAK,*CANCEL*,*EXIT*")
       (princ (strcat "\n** Error: " msg " **")))
   (princ))
 ;; Get Sysvars and store them
 (setq vl '("CMDECHO" "PEDITACCEPT") ov (mapcar 'getvar vl))
 ;; Set sys vars to what we want
 
 (mapcar 'setvar vl '(0 1))
 ;; Include IF statment to allow for a null SelectionSet
 (if (setq ss (ssget "_X" '((0 . "*POLYLINE"))))
   (command "_.pedit" "_M" ss "" "_L" "ON" ""))
 ;; Reset Sys Vars
 
 (mapcar 'setvar vl ov)
 (princ))

(defun c:Test (/ #SS)
 (and (setq #SS (ssget "_X" '((0 . "*POLYLINE"))))
      (foreach x (mapcar 'cadr (ssnamex #SS))
        (vl-catch-all-apply
          'vla-put-linetypegeneration
          (list (vlax-ename->vla-object x) :vlax-true)
        ) ;_ vl-catch-all-apply
      ) ;_ foreach
 ) ;_ and
 (princ)
) ;_ defun

(defun c:Test (/ #SS)
 (and (setq #SS (ssget "_X" '((0 . "*POLYLINE"))))
      (foreach x (ssnamex #SS)
        (vl-catch-all-apply
          'vla-put-linetypegeneration
          (list (vlax-ename->vla-object (cadr x)) :vlax-true)
        ) ;_ vl-catch-all-apply
      ) ;_ foreach
 ) ;_ and
 (princ)
) ;_ defun