尺寸标注帮助

casualmasters · 发表于 2022-7-6 14:24:07

您好，我需要帮助。请问有什么方法可以使autocad自动实现每个维度和级别的操作吗
我的意思是，我想，但每个点的维度可以是任何lisp或任何使我的生活更轻松的方法
图纸1.dwg

casualmasters · 发表于 2022-7-6 14:35:48

我想让autocad自动化每个点的级别，无论用什么方法都可以做到这一点

Lee Mac · 发表于 2022-7-6 14:36:55

这个怎么样？


(defun c:lazy_dim (/ doc spc bpt ss ept)
 (vl-load-com)
 (setq doc (vla-get-ActiveDocument
             (vlax-get-Acad-Object))
       spc (if (zerop (vla-get-activespace doc))
             (if (= (vla-get-mspace doc) :vlax-true)
               (vla-get-modelspace doc)
               (vla-get-paperspace doc))
             (vla-get-modelspace doc)))
 (if (and (setq bpt (getpoint "\nSelect Base Point: "))
          (princ "\nSelect Points...")
          (setq ss (ssget '((0 . "POINT")))))
   (foreach pt (mapcar 'vlax-3D-point
                 (vl-sort
                   (mapcar
                     (function
                       (lambda (x)
                         (cdr (assoc 10 (entget x)))))
                     (vl-remove-if 'listp
                       (mapcar 'cadr (ssnamex ss))))
                   (function
                     (lambda (x1 x2)
                       (> (cadr x1) (cadr x2))))))
     (if (setq ept
           (getpoint bPt "\nSelect Point to Dimension: "))
       (progn
         (vla-addDimRotated spc
           (vlax-3D-point bPt)
             (vlax-3D-point ePt) pt 0))))
   (princ "\n<< Incorrect Selection >>"))
 (princ))