围绕

eddablin · 发表于 2022-7-6 14:45:49

你好我有一个大型建筑的一楼平面图，并已将梁绘制到柱的中点。通常做法是将线条缩小，使其在平面上看起来像这样：

I------I

而不是

I-----------I

如果我有一段代码，使它们都围绕其中点进行缩放，而不是分别按其基点缩放每条线，这将节省我很多时间。有人有办法吗？

非常感谢！

Lee Mac · 发表于 2022-7-6 14:51:28

你需要按比例计算多少？它们都在自己的层上吗？它们是直线、多段线还是LW多段线？

eddablin · 发表于 2022-7-6 14:57:30

嗨，李。感谢您的回复。

它们都是线条。理想情况下，刻度可以是用户输入。如果不是0.8就好了。

谢谢

eddablin · 发表于 2022-7-6 15:06:09

哦，是的，它们都在同一层（称为“梁”）

Lee Mac · 发表于 2022-7-6 15:08:40

试一试：

copy


(defun c:scl  (/ ss scl)
 (vl-load-com)
 (or scale:def (setq scale:def 0.)
 (if (setq ss (ssget "X" (list (cons 0 "LINE")
                               (cons 8 "Beams")
                               (if (getvar "CTAB")
                                 (cons 410 (getvar "CTAB"))
                                 (cons 67 (- 1 (getvar "TILEMODE")))))))
   (progn
     (initget 6)
     (setq scl (getreal (strcat "\nSpecify Scale Factor <" (rtos scale:def) "> : ")))
     (or (not scl) (setq scale:def scl))
     (foreach x  (mapcar 'vlax-ename->vla-object
                         (mapcar 'cadr (ssnamex ss)))
       (vla-ScaleEntity x
         (vlax-3D-point
           (vlax-curve-getPointatDist x
             (/ (vla-get-length x) 2.0))) scale:def)))
   (princ "\n<!> No Lines Found <!>"))
 (princ))