[编程交流] 使用一个块生成多个

 
Option Explicit
Public Sub InsertClock()
   Dim objBRef As AcadBlockReference
   Dim varPoint As Variant
   Dim intMin As Integer
   Dim intHour As Integer
   Dim BProps As Variant
   Dim tmpProp As AcadDynamicBlockReferenceProperty
   Dim intI As Integer
   'ask user for where to place the clock, the prompt goes
   '   through the command window
   varPoint = ThisDrawing.Utility.GetPoint(, "click where you want the clock")
   'ask for time
   intHour = ThisDrawing.Utility.GetInteger(vbCrLf & "Hour: ")
   intMin = ThisDrawing.Utility.GetInteger(vbCrLf & "Minute: ")
   'insert block (the ones and zeros are for scale and rotation)
   Set objBRef = ThisDrawing.ModelSpace.InsertBlock(varPoint, "ClockFace.dwg", 1, 1, 1, 0)
   'get properties of the block
   BProps = objBRef.GetDynamicBlockProperties
   'go find minute and hour properties and change them
   'the minute rotation property is called 'Angle'
   'the hour rotation property is called 'Angle1'
   For intI = LBound(BProps) To UBound(BProps)
       'grab one property
       Set tmpProp = BProps(intI)
       'check for minute hand
       If tmpProp.PropertyName = "Angle" Then
           tmpProp.Value = Math.Atn(1) * 4 - (CDbl(intMin) / 60) * 2 * Math.Atn(1) * 4 - 2 * Math.Atn(1)
       End If
       'check for hour hand
       If tmpProp.PropertyName = "Angle1" Then
           tmpProp.Value = Math.Atn(1) * 4 - (CDbl(intHour) / 12) * 2 * Math.Atn(1) * 4 - 2 * Math.Atn(1)
       End If
   Next intI
   'update block
   objBRef.Update
End Sub