[综合讨论] 试图摆脱一个。shx fi

(defun c:ltfiles ( / lst2str a b c )
 (defun lst2str ( strlst )
   (if (cdr strlst)
     (strcat (strcase (car strlst)) ", " (lst2str (cdr strlst)))
     (strcase (car strlst))
     )
   )
 (setq b 0)
 (while (setq a (tblnext "LTYPE" (not a)))
   (setq b (1+ b))
   ((lambda ( ln / lst )
      (foreach styl (mapcar
                      'cdr
                      (vl-remove-if-not
                        '(lambda ( x )
                           (= (car x) 340)
                           )
                        (entget (tblobjname "LTYPE" ln))
                        )
                      )
        (foreach file (mapcar
                        'cdr
                        (vl-remove-if-not
                          '(lambda ( x )
                             (and (< 2 (car x) 5)
                                  (/= (cdr x) "")
                                  )
                             )
                          (entget styl)
                          )
                        )
          (if (not (member file lst))
            (setq lst (cons file lst))
            )
          )
        )
      (if lst
        (progn
          (setq c T)
          (princ (strcat "\nLinetype " ln " references file(s): " (lst2str lst)))
          )
        )
      )
     (cdr (assoc 2 a))
     )
   )
 (if c (textpage) (alert (strcat (itoa b) " linetypes processed & no shape files were found referenced.")))
 (princ)
 )