确定程序ID

;| Examples:
(MergePDFs 
  (strcat (getenv "userprofile") "\\Desktop\\Hale 515\\PDFs") ; in
  (strcat (getenv "userprofile") "\\Desktop\" "MergedPDFS.pdf") ; out
)
(MergePDFs 
  (list ; in
    (getfiled "Specify PDF file" (strcat (getenv "userprofile") "\\Desktop\") "pdf" 16)
    (strcat (getenv "userprofile") "\\Desktop\\I_Dont_Exist.pdf")
    (getfiled "Specify PDF file" (strcat (getenv "userprofile") "\\Desktop\") "pdf" 16)
    (getfiled "Specify PDF file" (strcat (getenv "userprofile") "\\Desktop\") "pdf" 16) ; You can cancel and provide nil if you want to
  ); list
  (strcat (getenv "userprofile") "\\Desktop\" "MergedPDFS.pdf") ; out
)
|;
; in - folder that contains .pdf files, or a list of ("\\.pdf" "\\.pdf" ..)
; out - path\\filename.pdf - Overwrites the existing (if theres one)
; If successful, Returns assoc list of '(( PageCount) ..)
(defun MergePDFs ( in out / *error* AcroApp L PD r )
  ; http://www.theswamp.org/index.php?topic=53974.msg586248#msg586248
  (defun *error* ( m )
    (and L (foreach x (mapcar 'car L) (vl-catch-all-apply 'vlax-invoke-method (list x 'Close)) (vl-catch-all-apply 'vlax-release-object (list x))))
    (and AcroApp
      (vl-catch-all-apply 'vlax-invoke-method (list AcroApp 'CloseAllDocs))
      (vl-catch-all-apply 'vlax-invoke-method (list AcroApp 'Exit))
      (vl-catch-all-apply 'vlax-release-object (list AcroApp))
    ); and
    (gc) (gc) (and m (princ m)) (princ)
  ); defun *error*
  
  (and in out
    (or (setq AcroApp (vlax-get-or-create-object "AcroExch.App")) (prompt "\nUnable to interfere with Acrobat object.") )
    (cond
      ( (eq 'STR (type in)) ; folder provided
        (setq L ((lambda (pat / tmp) (if (setq tmp (vl-directory-files pat "*.pdf" 1)) (mapcar (function (lambda (x) (list (vlax-get-or-create-object "AcroExch.PDDoc") (strcat pat "\" x)))) tmp))) in))
      )
      ( (vl-consp in) ; list of .pdf filepaths'n'names provided
        (setq L (mapcar (function (lambda (x) (list (vlax-get-or-create-object "AcroExch.PDDoc") x))) in))
      )
    ); cond
    (setq L (apply (function append) (mapcar (function (lambda (x) (if (eq :vlax-true (vlax-invoke-method (car x) 'Open (cond ((cadr x)) ("")))) (list (append x (list (vlax-invoke-method (car x) 'GetNumPages))))))) L)))
    (setq PD (caar L))
    (progn
      (foreach x (cdr L) ; L - assoc list of (#  )
        (if (eq :vlax-false (vlax-invoke-method PD 'InsertPages (1- (vlax-invoke PD 'GetNumPages)) (car x) 0 (caddr x) :vlax-true))
          (prompt (strcat "\nCannot insert pages from "" (cadr x) """))
        )
      )
      (or (eq :vlax-true (vlax-invoke-method PD 'Save 1 out)) ; 1 = PDSaveFull
        (prompt "\nCannot save the modified document")
      ); or
    ); progn
    (setq r (mapcar 'cdr L))
  ); and
  
  (*error* nil) r
); defun MergePDFs