怎么给添加的多行文字的字体加黑？

dazhangyu · 发表于 2003-9-24 14:53:00

我在添加多行文字时，想给文字加黑显示（也就是文字编辑中的B功能：粗体显示），可是用了textfontstyle方法也不好使，试了其它方法比如linewidth也不行，我现在已经是
哪位高手能帮兄弟一把？不胜感激！

gzy · 发表于 2003-9-24 18:08:00

是不是“黑体”啊？

mccad · 发表于 2003-9-24 21:01:00

他是说粗体，而不是黑体。


Sub TextB()
    Dim ent As AcadEntity
    Dim pnt As Variant
    On Error Resume Next
    Do
        ThisDrawing.Utility.GetEntity ent, pnt, "选择多行文字："
        Dim txt As AcadMText
        Set txt = ent
        If Err Then
            Err.Clear
        Else
            Exit Do
        End If
    Loop
    Dim str As String
    str = txt.TextString
    '加粗，其中SimSun为宋体，b1为加粗
    str = "{\fSimSun|b1;" & str & "}"
    txt.TextString = str
    ThisDrawing.Regen acActiveViewport
End Sub

efan2000 · 发表于 2003-9-24 21:08:00

也可以使用TextStyle对象的SetFont方法给文字加粗，它将对所有设置该文字样式的文字生效。
语法：RetVal = object.SetFont(Typeface, Bold, Italic, CharSet, PitchAndFamily)
例子：Sub Example_SetFont()
' This example finds the font information for the active text style.
' It then changes the font to bold.

Dim typeFace As String
Dim Bold As Boolean
Dim Italic As Boolean
Dim charSet As Long
Dim PitchandFamily As Long

ThisDrawing.ActiveTextStyle.GetFont typeFace, Bold, Italic, charSet, PitchandFamily

MsgBox "The current text style has the following font properties:" & vbCrLf _
         & "Typeface: " & typeFace & vbCrLf _
         & "Bold: " & Bold & vbCrLf _
         & "Italic: " & Italic & vbCrLf _
         & "Character set: " & charSet & vbCrLf _
         & &quotitch and Family: " & PitchandFamily

' Change the bold property
Bold = Not Bold

ThisDrawing.ActiveTextStyle.SetFont typeFace, Bold, Italic, charSet, PitchandFamily
MsgBox "The current text style has the following font properties:" & vbCrLf _
         & "Typeface: " & typeFace & vbCrLf _
         & "Bold: " & Bold & vbCrLf _
         & "Italic: " & Italic & vbCrLf _
         & "Character set: " & charSet & vbCrLf _
         & &quotitch and Family: " & PitchandFamily

' Reset the font
Bold = Not Bold
ThisDrawing.ActiveTextStyle.SetFont typeFace, Bold, Italic, charSet, PitchandFamily
End Sub