从o添加块属性

Guptil · 发表于 2022-7-5 13:18:10

尊敬的各位：，

在不同的组中花费了很多时间后，我开始了一个新的步骤，希望我能得到一个解决方案，实际上我有数百个没有块属性的块，但是我已经从另一个具有不同块名称的项目中定义了块，现在我想做的是将块属性添加到定义块中的块，但是我想保留几何体，插入点和X，Y，Z值与原始值相同，因为我有这么多的图纸要修改和这么多不同的块要更新，我正在寻找一些lisp的脚本，以便它可以快速完成，任何在这方面的帮助将不胜感激。

请查找包含这两个块的随附CAD文件。

David Bethel · 发表于 2022-7-5 13:40:17

这是可以做到的，但有几个局限性

基本引擎可能看起来像这样

copy


(defun c:att-snag (/ sn sd sp an ad sl ss i tn td tp
                     a10 a11 n10 n11)
  (while (not sn)
         (and (princ "\nSelect 1 SOURCE Insert...")
              (setq ss (ssget '((0 . "INSERT")(66 . 1))))
              (= (sslength ss) 1)
              (setq sn (ssname ss 0)
                    sd (entget sn)
                    sp (cdr (assoc 10 sd))
                    an (entnext sn)
                    ad (entget an))))
  (while (= "ATTRIB" (cdr (assoc 0 ad)))
         (setq sl (cons ad sl)
               an (entnext an)
               ad (entget an)))
  (and (princ "\nSelect TARGET Inserts...")
       (setq ss (ssget '((0 . "INSERT")(66 . 0))))
       (setq i 0)
       (while (setq tn (ssname ss i))
              (setq td (entget tn)
                    tp (cdr (assoc 10 td)))
              (setq td (append td (list (cons 66 1))))
              (entmake td)
              (foreach a (reverse sl)
                (setq a10 (mapcar '- (cdr (assoc 10 a)) sp))
                (setq n10 (mapcar '+ tp a10))
                (setq a11 (mapcar '- (cdr (assoc 11 a)) sp))
                (setq n11 (mapcar '+ tp a11))
                (setq a (subst (cons 10 n10) (assoc 10 a) a))
                (setq a (subst (cons 11 n11) (assoc 11 a) a))
                (entmake a))
              (entmake (list (cons 0 "SEQEND")(cons 8 "0")))
              (entdel tn)
              (redraw (entlast))
              (setq i (1+ i))))
  (prin1))

这只是将源属性添加到目标插入中

它不会：
[列表]

重新定义目标块定义

处理源插入旋转、缩放和OCS

删除属性值（复制源属性值）

保留属性提示
它可以：
[列表]

匹配从源插入点到属性的属性偏移
我相信你可能还需要处理一些其他的怪癖。

-大卫

David Bethel · 发表于 2022-7-5 14:02:42

这里有一种不同的方法，使用“复制”命令并引用源几何体。

copy


(defun c:att-snac (/ sn ss sd sp tn td tp ss i ed)
  (while (not sn)
         (and (princ "\nSelect 1 SOURCE Insert...")
              (setq ss (ssget '((0 . "INSERT")(66 . 1))))
              (= (sslength ss) 1)
              (setq sn (ssname ss 0)
                    sd (entget sn)
                    sp (cdr (assoc 10 sd)))))
  (and (princ "\nSelect TARGET Inserts...")
       (setq ss (ssget '((0 . "INSERT")(66 . 0))))
       (setq i 0)
       (while (setq tn (ssname ss i))
              (setq td (entget tn)
                    tp (cdr (assoc 10 td)))
              (command "_.COPY" sn "" sp tp)
              (setq ed (entget (entlast)))
              (entmod (subst (assoc 2 td) (assoc 2 sd) ed))
              (entdel tn)
              (redraw (entlast))
              (setq i (1+ i))))
  (prin1))

Guptil · 发表于 2022-7-5 14:11:48

感谢David的支持，
实际上，它是可行的，但正如你所说，有一些局限性，其中之一是，它改变了比例，（X，Y）值，然后它复制了属性，但是我在块编辑器中看不到它们，甚至在Battman中，我也看不到列表中的块。还有，我们可以将块重命名为源，然后删除源吗？

David Bethel · 发表于 2022-7-5 14:24:52

很高兴它起了一些作用。难怪块编辑器和Battman不能工作，因为我没有修改目标的块表定义。复制例程
应该处理比例和旋转。重命名充满了问题。您可以简单地将源插入添加到选择集

-大卫

[编程交流] 从o添加块属性

发表回复

精选推荐