更容易递归地构建

Jef! · 发表于 2022-7-5 13:19:52

这不是我第一次尝试，但我总是设法找到另一条路线。这次我不想要任何“硬编码的替代品”，所以。。。请跟我谈谈。我从一个类似于ssnamex的选择部分的列表中选择（因此其长度可以变化）
由于列表的长度可能不同，我认为“递归”，但fast发现，虽然递归构建有点简单，但递归解构似乎完全是另一回事。（可以做到吗？）
到目前为止，我的最佳尝试是删除所有不是坐标的内容，但列表结构与原始列表相同，如下所示

copy


;Not quite there yet!
(defun keepcoords (L)
   (if (listp L)
       (if (and (atom (car L))
                (atom (cadr L))
                (atom (caddr L))
           )
           L
           (mapcar '(lambda (x)
                      (keepcoords x)
                    )
                   L
           )
       )
   )
)
;returns that....
((nil (nil (269.157 85.9418 0.0)) (nil (272.343 85.9418 0.0)) (nil (272.343 59.9463 0.0)) (nil (269.157 59.9463 0.0)))
  (nil (nil (273.021 84.9263 0.0)) (nil (274.851 84.9263 0.0)) (nil (274.851 83.3016 0.0)) (nil (273.021 83.3016 0.0)))
  (nil (nil (275.258 65.4297 0.0)) (nil (279.528 65.4297 0.0)) (nil (279.528 60.6233 0.0)) (nil (275.258 60.6233 0.0)))
  (nil (nil (280.206 72.2671 0.0)) (nil (283.596 72.2671 0.0)) (nil (283.596 69.5592 0.0)) (nil (280.206 69.5592 0.0))))

我需要的是得到一个只包含坐标的列表，就像这样
我知道我可以“硬编码”一个解决方案，该解决方案适用于（并且仅适用于）这种特定类型的列表，但我在这里的目标是制作一个函数，该函数可以只提取任意长度和形态的列表的点坐标，递归似乎是实现它的唯一途径。我可怜的大脑现在坏了。我需要一些新的观点。请解开我的大脑

Jef! · 发表于 2022-7-5 13:23:31

啊，我可能忘了提到其他任意决定的标准，例如“只有一个函数”和“没有子函数”。。因为

copy


(defun keepcoords ( L / helper ret)
  (defun helper ( L )
    (if (listp L)
       (if (and (atom (car L))
                (numberp (car L))
                (atom (cadr L))
                (numberp (cadr L))
                (atom (caddr L))
                (numberp (caddr L))
                (= 3 (length L))
           )
           (setq ret (cons L ret));L
           (mapcar '(lambda (x)
                      (helper x)
                    )
                   L
           )
       )
   )
  )
  (helper L)
  ret
)

似乎不如简单的建筑递归优雅。但它是有效的。尽管如此，如果你能找到一种在单个功能中实现它的方法，请随时发布。

Lee Mac · 发表于 2022-7-5 13:29:06

也许是这样？

copy


(defun coords ( lst )
    (if (and lst (listp lst))
        (if (and (< 1 (length lst) 4) (vl-every 'numberp lst))
            (list lst)
            (append (coords (car lst)) (coords (cdr lst)))
        )
    )
)

Jef! · 发表于 2022-7-5 13:32:24

啊！对！我的一次尝试非常接近于此，但并没有将坐标保持在列表中，而是将它们展平到一个列表中，因为我返回的是lst而不是（list lst）。我总是尽量避免使用append，显然我甚至不知道如何正确使用它。这是我的
一旦有人睁开眼睛，我们所看到的一切都是疯狂的。您的“（and lst（listp lst））”很好地提醒了我们，（listp nil）返回T，这解释了为什么在我疯狂使用嵌套的ifs、mapcars、lambdas、子函数和局部变量之前，我试图修改append版本时出现了一些内部堆栈限制问题。正如谚语所说：“我们活着，读书，学习。”
谢谢李！
编辑：为（<1（长度lst）4）&（vl every’numberp lst）致敬。比我做的更优雅。

Grrr · 发表于 2022-7-5 13:35:42

上述检查等于（vl consp lst）

copy


(defun f ( L )
  (cond 
    ( (atom L) nil)
    ( (append (f (car L)) (f (cdr L))) )
    ( (and (= 3 (length L)) (vl-every 'numberp L)) (list L) )
  )
)

Stefan BMR · 发表于 2022-7-5 13:38:08

另一个

copy


(defun coords (lst)
  (apply 'append
    (mapcar
     '(lambda (x)
        (cond
          ((atom x) nil)
          ((vl-every 'numberp x) (list x))
          ((coords x))
        )
      )
      lst
    )
  )
)