需要Lisp：将节点放置在cen

Jadeous · 发表于 2022-7-5 15:07:06

你好我已经有一段时间没来了。想念你们。

我需要询问是否有人有或可以编写一个Lisp例程，将节点放置在图形中多个（100+）圆的中心。我需要一些2D的东西。三维中的高程不是问题。

听起来很简单，但我的同事们都被难住了。

任何帮助都会很棒！

正在运行：
AutoCad 2012和AutoCad MEP 2012
Windows 7 Professional 64位

MSasu · 发表于 2022-7-5 15:14:47

从上一个线程中解救出来，并进行了一些调整：

copy

;Add Points to Circles (11-VII-2012)
(defun c:APC( / ssetCircles countCircles itemCircle assocCircle assocPoint  )
(if (setq ssetCircles (ssget "_X" '((0 . "CIRCLE"))))
 (repeat (setq countCircles (sslength ssetCircles))
  (setq itemCircle (ssname ssetCircles 0)
        assocCircle (entget itemCircle)
        assocPoint  '((0 . "POINT")))
  (foreach codeDXF '(10 8 410 210)
   (setq assocPoint (append assocPoint (list (assoc codeDXF assocCircle))))
  )
  (if (assoc 62 assocCircle) 
   (setq assocPoint (append assocPoint (list (assoc 62 assocCircle)))))
  (if (assoc 6 assocCircle) 
   (setq assocPoint (append assocPoint (list (assoc 6 assocCircle))))) ;???
  (entmakex assocPoint)
  (ssdel itemCircle ssetCircles)
 )
)
(prompt (strcat "\nReplaced " (itoa countCircles) " circles."))
(princ)
)

Tharwat · 发表于 2022-7-5 15:17:14

大概

copy


(defun c:Test (/ ss)
 (if (setq ss (ssget "_x" '((0 . "CIRCLE"))))
   ((lambda (i / sn e)
      (while (setq sn (ssname ss (setq i (1+ i))))
         (entmakex (list '(0 . "POINT") (assoc 10 (setq e (entget sn)))(assoc 8 e)))))
     -1
   )
   (princ)
 )
 (princ)
)

Jadeous · 发表于 2022-7-5 15:22:51

“APC”非常接近。

我使用此命令的情况是在图形中使用圆进行外部参照以表示管道支架。我需要在当前图形中的圆心内放置一个节点，然后拆离外部参照。因此，没有必要替换圆。

也许有一个Lisp来寻找中心，而不是具体的圆。

Lee Mac · 发表于 2022-7-5 15:26:46

以下内容适用于具有任何方向、比例或旋转的块/动态块/外部参照：

copy


[color=GREEN];; Points at Circle Centres within Block  -  Lee Mac[/color]
[color=GREEN];; Prompts for selection of a block and creates points in modelspace[/color]
[color=GREEN];; at the centre of every circle in the selected block[/color]
([color=BLUE]defun[/color] c:ptcirblk ( [color=BLUE]/[/color] bd en ml )
   ([color=BLUE]while[/color]
       ([color=BLUE]progn[/color] ([color=BLUE]setvar[/color] 'errno 0) ([color=BLUE]setq[/color] en ([color=BLUE]car[/color] ([color=BLUE]entsel[/color] [color=MAROON]"\nSelect Block: "[/color])))
           ([color=BLUE]cond[/color]
               (   ([color=BLUE]=[/color] 7 ([color=BLUE]getvar[/color] 'errno))
                   ([color=BLUE]princ[/color] [color=MAROON]"\nMissed, try again."[/color])
               )
               (   ([color=BLUE]=[/color] 'ename ([color=BLUE]type[/color] en))
                   ([color=BLUE]if[/color] ([color=BLUE]/=[/color] [color=MAROON]"INSERT"[/color] ([color=BLUE]cdr[/color] ([color=BLUE]assoc[/color] 0 ([color=BLUE]entget[/color] en))))
                       ([color=BLUE]princ[/color] [color=MAROON]"\nSelected Object is not a Block."[/color])
                   )
               )
           )
       )
   )
   ([color=BLUE]if[/color] en
       ([color=BLUE]progn[/color]
           ([color=BLUE]setq[/color] bd ([color=BLUE]tblobjname[/color] [color=MAROON]"BLOCK"[/color] ([color=BLUE]cdr[/color] ([color=BLUE]assoc[/color] 2 ([color=BLUE]entget[/color] en))))
                 ml (RefGeom en)
           )
           ([color=BLUE]while[/color] ([color=BLUE]setq[/color] bd ([color=BLUE]entnext[/color] bd))
               ([color=BLUE]if[/color] ([color=BLUE]=[/color] [color=MAROON]"CIRCLE"[/color] ([color=BLUE]cdr[/color] ([color=BLUE]assoc[/color] 0 ([color=BLUE]entget[/color] bd))))
                   ([color=BLUE]entmake[/color]
                       ([color=BLUE]list[/color]
                          '(0 . [color=MAROON]"POINT"[/color])
                           ([color=BLUE]cons[/color] 10 ([color=BLUE]mapcar[/color] '[color=BLUE]+[/color] (mxv ([color=BLUE]car[/color] ml) ([color=BLUE]cdr[/color] ([color=BLUE]assoc[/color] 10 ([color=BLUE]entget[/color] bd)))) ([color=BLUE]cadr[/color] ml)))
                       )
                   )
               )
           )
       )
   )
   ([color=BLUE]princ[/color])
)
[color=GREEN];; RefGeom (gile)[/color]
[color=GREEN];; Returns a list which first item is a 3x3 transformation matrix (rotation,[/color]
[color=GREEN];; scales, normal) and second item the object insertion point in its parent[/color]
[color=GREEN];; (xref, block or space)[/color]
[color=GREEN];;[/color]
[color=GREEN];; Argument : an ename[/color]
([color=BLUE]defun[/color] RefGeom ( ename [color=BLUE]/[/color] elst ang norm mat )
   ([color=BLUE]setq[/color] elst ([color=BLUE]entget[/color] ename)
         ang  ([color=BLUE]cdr[/color] ([color=BLUE]assoc[/color] 50 elst))
         norm ([color=BLUE]cdr[/color] ([color=BLUE]assoc[/color] 210 elst))
   )
   ([color=BLUE]list[/color]
       ([color=BLUE]setq[/color] mat
           (mxm
               ([color=BLUE]mapcar[/color] '([color=BLUE]lambda[/color] ( v ) ([color=BLUE]trans[/color] v 0 norm [color=BLUE]t[/color]))
                  '(
                       (1.0 0.0 0.0)
                       (0.0 1.0 0.0)
                       (0.0 0.0 1.0)
                   )
               )
               (mxm
                   ([color=BLUE]list[/color]
                       ([color=BLUE]list[/color] ([color=BLUE]cos[/color] ang) ([color=BLUE]-[/color] ([color=BLUE]sin[/color] ang)) 0.0)
                       ([color=BLUE]list[/color] ([color=BLUE]sin[/color] ang) ([color=BLUE]cos[/color] ang)     0.0)
                      '(0.0 0.0 1.0)
                   )
                   ([color=BLUE]list[/color]
                       ([color=BLUE]list[/color] ([color=BLUE]cdr[/color] ([color=BLUE]assoc[/color] 41 elst)) 0.0 0.0)
                       ([color=BLUE]list[/color] 0.0 ([color=BLUE]cdr[/color] ([color=BLUE]assoc[/color] 42 elst)) 0.0)
                       ([color=BLUE]list[/color] 0.0 0.0 ([color=BLUE]cdr[/color] ([color=BLUE]assoc[/color] 43 elst)))
                   )
               )
           )
       )
       ([color=BLUE]mapcar[/color] '[color=BLUE]-[/color] ([color=BLUE]trans[/color] ([color=BLUE]cdr[/color] ([color=BLUE]assoc[/color] 10 elst)) norm 0)
           (mxv mat ([color=BLUE]cdr[/color] ([color=BLUE]assoc[/color] 10 ([color=BLUE]tblsearch[/color] [color=MAROON]"BLOCK"[/color] ([color=BLUE]cdr[/color] ([color=BLUE]assoc[/color] 2 elst))))))
       )
   )
)
[color=GREEN];; Matrix Transpose  -  Doug Wilson[/color]
[color=GREEN];; Args: m - nxn matrix[/color]
([color=BLUE]defun[/color] trp ( m )
   ([color=BLUE]apply[/color] '[color=BLUE]mapcar[/color] ([color=BLUE]cons[/color] '[color=BLUE]list[/color] m))
)
[color=GREEN];; Matrix x Vector  -  Vladimir Nesterovsky[/color]
[color=GREEN];; Args: m - nxn matrix, v - vector in R^n[/color]
([color=BLUE]defun[/color] mxv ( m v )
   ([color=BLUE]mapcar[/color] '([color=BLUE]lambda[/color] ( r ) ([color=BLUE]apply[/color] '[color=BLUE]+[/color] ([color=BLUE]mapcar[/color] '[color=BLUE]*[/color] r v))) m)
)
[color=GREEN];; Matrix x Matrix  -  Vladimir Nesterovsky[/color]
[color=GREEN];; Args: m,n - nxn matrices[/color]
([color=BLUE]defun[/color] mxm ( m n )
   (([color=BLUE]lambda[/color] ( a ) ([color=BLUE]mapcar[/color] '([color=BLUE]lambda[/color] ( r ) (mxv a r)) m)) (trp n))
)
([color=BLUE]princ[/color])

Jadeous · 发表于 2022-7-5 15:27:11

如果有帮助，我正在与TSI看台合作。每个展台周围都有一个圆圈，表示“净空区域”。

如果我分解支架，圆形消失，支架的其余部分变成3d面。

也许这就是为什么李·麦克的Lisp程序不能作画的原因。TSI项不被视为块。

如果我能找到一种从TSI支架中提取该圆的方法，我可以在此线程上使用第一个lisp，或者找到一个可以识别项目中圆的lisp。