多段线到文本

jan_ek · 发表于 2022-7-5 15:20:03

你好
你好，我有一个简单的问题。
如何使用LISP计算附件（多段线）中显示的值？

marko_ribar · 发表于 2022-7-5 15:36:49

你的意思是第二个例子：

100;90;300;45;424;-45;300;-90;100

Lee Mac · 发表于 2022-7-5 15:48:15

举个简单的例子：

(defun bearings ( ent / enx lst )
   (setq enx (entget ent)
         lst (mapcar 'cdr (vl-remove-if-not '(lambda ( x ) (= 10 (car x))) enx))
   )
   (if (= 1 (logand 1 (cdr (assoc 70 enx))))
       (setq lst (append lst (list (car lst))))
   )
   (if (cdr lst)
       (cons (distance (car lst) (cadr lst))
           (apply 'append
               (mapcar
                   (function
                       (lambda ( a b c )
                           (list (* 180.0 (/ (- (rem (+ pi pi (- (angle b a) (angle b c))) (+ pi pi)) pi) pi)) (distance b c))
                       )
                   )
                   lst (cdr  lst) (cddr lst)
               )
           )
       )
   )
)

要测试：

copy

(defun c:test ( / sel )
   (if (setq sel (ssget "_+.:E:S" '((0 . "LWPOLYLINE") (-4 . "<NOT") (-4 . "<>") (42 . 0.0) (-4 . "NOT>"))))
       (print (bearings (ssname sel 0)))
   )
   (princ)
)