[编程交流] 创建随机图层和Assig

(setq ss (ssget "_:L" '((0 . "LWPOLYLINE"))))

(defun c:assignrndlayerstoobjects ( / rnd *a* LM:True->RGB ss i e nn n rndn0-1 rndnumb1-16777216 rgb enx ) ; lexical global *a* localized
 (defun rnd ( / ti tis ns n ) ; *a* - global number variable ; return - n random number from 0 to 9
   (setq ti (car (_vl-times)))
   (setq tis (itoa ti))
   (setq ns (substr tis (strlen tis)))
   (setq n (atoi ns))
   (if (null *a*)
     (setq *a* n)
     (progn
       (while (= *a* n)
         (setq ti (car (_vl-times)))
         (setq tis (itoa ti))
         (setq ns (substr tis (strlen tis)))
         (setq n (atoi ns))
       )
       (setq *a* n)
     )
   )
   n
 )
 ;; True -> RGB  -  Lee Mac
 ;; Args: c - [int] True Colour
 (defun LM:True->RGB ( c )
   (mapcar '(lambda ( x ) (lsh (lsh (fix c) x) -24)) '(8 16 24))
 )
 (setq ss (ssget "_:L"))
 (repeat (setq i (sslength ss))
   (setq e (ssname ss (setq i (1- i))))
   (setq nn "")
   (repeat 15
     (setq n (itoa (rnd)))
     (setq nn (strcat n nn))
   )
   (setq rndn0-1 (atof (strcat "0." nn)))
   (setq rndnumb1-16777216 (1+ (fix (* 16777216 rndn0-1))))
   (while (tblsearch "LAYER" (itoa rndnumb1-16777216))
     (setq nn "")
     (repeat 15
       (setq n (itoa (rnd)))
       (setq nn (strcat n nn))
     )
     (setq rndn0-1 (atof (strcat "0." nn)))
     (setq rndnumb1-16777216 (1+ (fix (* 16777216 rndn0-1))))
   )
   (setq rgb (LM:True->RGB rndnumb1-16777216))
   (vl-cmdf "_.-LAYER" "_M" (itoa rndnumb1-16777216) "_C" "_T" (strcat (itoa (car rgb)) "," (itoa (cadr rgb)) "," (itoa (caddr rgb))))
   (while (< 0 (getvar 'cmdactive)) (vl-cmdf ""))
   (setq enx (entget e))
   (setq enx (subst (cons 8 (itoa rndnumb1-16777216)) (assoc 8 enx) enx))
   (entupd (cdr (assoc -1 (entmod enx))))
 )
 (princ)
)

(defun C:test ( / pref SS accm lyrs i enx tmp )
 (and 
   LM:rand LM:randrange
   (setq pref (getstring "\nLayer prefix: " t))
   (setq SS (ssget "_:L-I"))
   (setq accm (vla-GetInterfaceObject (vlax-get-acad-object) (strcat "AutoCAD.AcCmColor." (substr (getvar 'acadver) 1 2))))
   (progn (vla-put-ColorMethod accm acColorMethodByRGB) t)
   (setq lyrs (vla-get-Layers (vla-get-ActiveDocument (vlax-get-acad-object))))
   (repeat (setq i (sslength SS))
     (setq enx (entget (ssname SS (setq i (1- i)))))
     (entmod (subst (cons 8 (setq tmp (strcat pref (cdr (assoc 5 enx))))) (assoc 8 enx) enx))
     (apply 'vla-SetRGB (cons accm (mapcar 'LM:randrange '(0 0 0) '(255 255 255))))
     (vla-put-TrueColor (vla-item lyrs tmp) accm)
   )
 )
 (and (eq 'VLA-OBJECT (type accm)) (vl-catch-all-apply 'vlax-release-object (list accm)))
 (princ)
); defun 
(vl-load-com) (princ)
;; Random in Range  -  Lee Mac
;; Returns a pseudo-random integral number in a given range (inclusive)
(defun LM:randrange ( a b )
 (+ (min a b) (fix (* (LM:rand) (1+ (abs (- a b))))))
)
;; Rand  -  Lee Mac
;; PRNG implementing a linear congruential generator with
;; parameters derived from the book 'Numerical Recipes'
(defun LM:rand ( / a c m )
 (setq m   4294967296.0
   a   1664525.0
   c   1013904223.0
   $xn (rem (+ c (* a (cond ($xn) ((getvar 'date))))) m)
 )
 (/ $xn m)
)

(defun c:test2 ( / doc la ss ob hd i )
(and (setq doc '((l / doc) (setq doc (vlax-get-acad-object)) (foreach x l (setq doc (vlax-get doc x))))
          la  (doc '(ActiveDocument Layers)))
   (ssget ":L" '((0 . "LWPOLYLINE"))
          )
    (vlax-for ob (setq ss (doc '(ActiveDocument ActiveSelectionSet)))
      (setq hd (vla-get-handle ob) i (rem (LM:base->dec hd 16) 255 ))
      (vla-add la hd) (vla-put-layer ob hd) (vla-put-color ob i )
      )
 (mapcar 'vlax-release-object (list la ss) )
    )
(princ)
)
(vl-load-com)
;; Base to Decimal  -  Lee Mac
;; Converts an number in an arbitrary base to decimal.
;; n - [str] string representing number to convert
;; b - [int] base of input string
;; Returns: [int] Decimal representation of supplied number
(defun LM:base->dec ( n b ) ;; www.lee-mac.com
   (   (lambda ( f ) (f (mapcar '(lambda ( x ) (- x (if (< x 65) 48 55))) (reverse (vl-string->list n)))))
       (lambda ( c ) (if c (+ (* b (f (cdr c))) (car c)) 0))
   )
)