玩mapcar和lambda

DGRL · 发表于 2022-7-5 15:24:03

亲爱的程序员

在使用mapcar功能时，我想知道下一个是否可行

我会有一个包含多个列表的列表，即（（“ent1”ent2“ent3”）（“ent11”ent22“ent33”））

现在我想把它们结合在一起

（（“ent1”“ent11”）（“Ent2”“ent22”）（“ent3”“ent23”））

这很容易做到，但现在我真正想尝试的是

我们采用相同的列表，但该列表附带未知数量的子列表
在我的例子中，我只取了2个子列表，但因为我从txt中读取，所以它可以是10或100个子列表或介于两者之间的任何数字

所以我们开始

（setq list1（mapcar‘list（car’（“ent1”“ent2”“ent3”）（“ent11”“ent22”“ent33”））（cadr’（（“ent1”“ent2”“ent3”）（“ent11”“ent22”“ent33”））））

当你不知道子列表的数量时，怎么写这个？
i、 e（setq list1（mapcar列表（foreach x列表……）。。。。。。。

或

（setq list1（mapcar列表（λ……）。。。。。。。

Jef! · 发表于 2022-7-5 15:28:13

嗨，DroiteGaucheRightLeft！

没有什么特别的，没有错误捕捉（如果你想处理不均匀的子列表，它会变得指数级的复杂，这取决于它需要如何处理）。。。下面是一个如何实现这一点的示例。

copy

(defun test (lst / x lst ret)
 (setq x 0)
 (repeat (length (car lst))
         (foreach itm lst (setq ret (cons (nth x itm) ret)))
         (setq x (1+ x))
 )
 (reverse ret)
)

按如下方式将列表馈送到函数。。。

干杯

Lee Mac · 发表于 2022-7-5 15:33:47

copy

(apply 'mapcar (cons 'list <your-list>))

copy

_$ (apply 'mapcar (cons 'list '(("ent1" " ent2" "ent3")("ent11" "ent22" "ent33")("ent111" "ent222" "ent333"))))
(("ent1" "ent11" "ent111") (" ent2" "ent22" "ent222") ("ent3" "ent33" "ent333"))

Jef! · 发表于 2022-7-5 15:37:28

末日！我误读了返回值的格式，一个列表的列表，而不仅仅是一个列表。哦，好吧。

copy

(defun test (lst / x lst ret ret2)
 (setq x 0)
 (repeat (length (car lst))
         (foreach itm lst (setq ret (cons (nth x itm) ret)))
         (setq x (1+ x))
         (setq ret2 (cons (reverse ret) ret2))
         (setq ret nil)
 )
(reverse ret2)
)

既然你能用复数，为什么还要用复数？
（李做得很好！）

DGRL · 发表于 2022-7-5 15:38:14

嗨，杰夫！

很好的一个名字lol

现在，我想处理偶数子列表，其余的将稍后提供
谢谢你提供的两个例子，当我需要你提供的第一个时，你永远不知道

@李·麦克。

短而有力：-）

rlx · 发表于 2022-7-5 15:42:35

李出世了（我想我知道他来自哪里：加里弗雷）

不幸的是，我自己做得再好不过了。。。

copy

   (mapcar 'list '(1 2 3) '(11 12 13) '(21 23 23))

李，什么时候，或者如果你不再需要或使用它，我可以借用你的大脑吗

gr.Rlx

Grrr · 发表于 2022-7-5 15:47:49

这听起来像是一个黑色幽默，可能是一个很好的器官捐赠广告。

之前我在调查这个
并且认为guy使用的算法似乎有点复杂（顺便说一句，让我想起了Jef的），所以我想知道用LISP做这件事有多难。答案是：一点也不难-

copy

(defun RotateMatrix ( mat )
 (setq mat (mapcar 'reverse (apply 'mapcar (cons 'list mat))))
 (foreach x mat (print x))
)

它像视频中那样旋转：

copy


(RotateMatrix
 '(
   (0 1)
   (2 3)
 )
)
>>
(2 0) 
(3 1)
(RotateMatrix
 '(
   (0 1 2)
   (3 4 5)
   (6 7 
 )
)
>>
(6 3 0) 
(7 4 1) 
(8 5 2)
(RotateMatrix
 '(
   (0 1 2 3)
   (4 5 6 7)
   (8 9 10 11)
   (12 13 14 15)
 )
)
>>
(12 8 4 0) 
(13 9 5 1) 
(14 10 6 2) 
(15 11 7 3)

然后我记得这项技术（对我来说）是由李和他的数学家演示的-所以当我把这些点连接起来时············································。

rlx · 发表于 2022-7-5 15:51:58

现在看看谁在说黑色幽默whaha。。。

gr.Rlx

Lee Mac · 发表于 2022-7-5 15:54:47

谢谢大家的好意和恭维。

@Grrr、链表（构建LISP的基础）及其固有的灵活性（与数组的相对刚性相比）非常适合复杂的操作，否则通过交换数组中的元素来实现相对困难。

FWIW，有几种方法可以编写“旋转矩阵”函数，包括左旋转和右旋转-

copy

(defun rmat ( m )
   (mapcar 'reverse (apply 'mapcar (cons 'list m)))
)
(defun rmat2 ( m )
   (apply 'mapcar (cons 'list (reverse m)))
)
(defun lmat ( m )
   (apply 'mapcar (cons 'list (mapcar 'reverse m)))
)
(defun lmat2 ( m )
   (reverse (apply 'mapcar (cons 'list m)))
)

Grrr · 发表于 2022-7-5 15:58:33

随着时间的推移，我意识到用LISP操作数据是多么容易，现在我完全理解了切换到另一种编程语言的困难（只是感觉没有那么灵活）。
之前很少有线程向Rlx提及LISP的优势。
但我仍然认为学习更多像Jef这样的“通用”处理是一个很好的做法！提供，由于最终的语言切换。

谢谢李，我从我的档案中找到了这个函数（当时我正试图用它和grread一起找出一些有趣的东西）。

主题外：
我左脑只想到旋转一些坐标，
这转化为另一种想法，即使用2D投影+grread，用[W/A/S/D]键“倾斜”投影/透视向上/向下/左/右。
想象一下，看看你的例子#1（在我的脑海里看起来很酷）。

您提供的功能可能对其他人也很方便，尤其是对DGRL（从他的兴趣来看，我认为他有潜力成为“我们中的一员”）。

DGRL，请注意，李是（最好的？/最好的）列表操纵器之一，所以我们使用的双关语不是偶然的。

[编程交流] 玩mapcar和lambda

发表回复

精选推荐