[编程交流] 在冻结层上搜索文本

(if (setq s (ssget "_X" '((0 . "TEXT") (1 . "YourTextHere"))))
   (cdr (assoc 8 (entget (ssname s 0))))
)

(while (and (setq d (tblnext "LAYER" (not d))) (not s))
 (and 
   (ssget "_X" (list '(0 . "TEXT") '(1 . "YourTextHere") (cons 8 (cdr (assoc 2 d)))))
   (setq s d)
 )
)
s

(defun c:findtextlayer ( / enx idx lay lst sel str )
   (cond
       (   (= "" (setq str (getstring t "\nSpecify text to find: ")))
           (princ "\nNo text entered.")
       )
       (   (setq sel (ssget "_X" (list '(0 . "TEXT") (cons 1 str))))
           (repeat (setq idx (sslength sel))
               (setq idx (1- idx)
                     enx (entget (ssname sel idx))
                     lay (cdr (assoc 8 enx))
               )
               (if (not (member lay lst)) (setq lst (cons lay lst)))
           )
           (princ (strcat "\nSingle-line text with content "" str "" was found on the layers: "))
           (foreach lay lst (princ "\n\t") (prin1 lay))
       )
       (   (princ (strcat "\nNo single-line text with text content equal to "" str "" was found.")))
   )
   (princ)
)

(defun c:foo (/ a d e f l n s x)
 ;; RJP 2.6.2018
 ;; Creates a layer filter from a selection of objects
 (cond
   ((null (setq s (ssget))) (print "Bye..."))
   ((null
      (and (setq a (cdr (assoc 330 (entget (tblobjname "layer" (getvar 'clayer))))))
    (setq d (cdr (assoc -1 (dictsearch (cdr (assoc 360 (entget a))) "ACAD_LAYERFILTERS"))))
      )
    )
    (print "No layer filter dictionary...")
   )
   (t
    (foreach x        (vl-remove-if 'listp (mapcar 'cadr (ssnamex s)))
      (and (not (member (setq l (cdr (assoc 8 (entget x)))) f)) (setq f (cons l f)))
    )
    (setq n (strcat (getenv "username") "_SelectionFilter"))
    (and (setq e (dictsearch d n)) (entdel (cdr (assoc -1 e))))
    (dictadd d
      n
      (entmakex        (list '(0 . "xrecord")
                      '(100 . "AcDbXrecord")
                      '(280 . 1)
                      (cons 1 n)
                      (cons 1 (apply 'strcat (mapcar '(lambda (x) (strcat x ",")) f)))
                      '(1 . "*")
                      '(1 . "*")
                      '(70 . 0)
                      '(1 . "*")
                      '(1 . "*")
                )
      )
    )
    (command "_.+layer" n)
    ;; Qsave regenerates layer palette to show correct filter .. bit of a kludge
    (command "_.qsave")
   )
 )
 (princ)
)