[LISP]关于group name

aaddff · 发表于 2004-4-30 16:07:00

请问如何用lisp得到一个group name之后炸开呢？
一个group经copy后，其name 会改变，怎样知道有几个内容一样，但name不一样的group 呢?

龙龙仔 · 发表于 2004-5-3 09:18:00

;;1.請問如何用lisp得到一個group name之後炸開呢？
;;////////////////////////////////////////////////////////////////
;;
;;    GroupNames ( Ename )
;;
;; Copyright c 2001 Michael Puckett - All Rights Reserved
;;
;;////////////////////////////////////////////////////////////////
;;
;;    Return a list of the group names the entity is a child of,
;;    innermost first.
;;
;;////////////////////////////////////////////////////////////////
(defun GROUPNAMES (ENAME / KEY DICT RESULT)
   (setq
   KEY    (cons 340 ENAME)
   DICT (dictsearch (namedobjdict) "acad_group")
   )
   (while (setq DICT (member (assoc 3 DICT) DICT))
   (if (member KEY (entget (cdadr DICT)))
   (setq RESULT (cons (cdar DICT) RESULT))
   )
   (setq DICT (cddr DICT))
   )
   (reverse RESULT)
)
;;炸開物件所屬群組
;;BY 龍龍仔(LUCAS)
(defun C:EXPGROUP (/ HOLDECHO GROUPNAMES_LST NAME)
   (setq HOLDECHO (getvar "cmdecho"))
   (setq GROUPNAMES_LST (GROUPNAMES (car (entsel "\nSelect object: "))))
   (setvar "cmdecho" 0)
   (foreach NAME GROUPNAMES_LST
   (command "_.GROUP" "E" NAME)
   (prompt (strcat "\n炸開群組名稱: " NAME))
   )
   (setvar "cmdecho" HOLDECHO)
   (princ)
)
;;2.一個group經copy後，其name 會改變，怎樣知道有幾個內容一樣，但name不一樣的group 呢?
;;->很難!!