为什么没有进位了？？？

ht1480 · 发表于 2022-8-2 09:57:00

搞不懂在编辑器里运行下来没有进位，一行行运行也没进位
命令行里单独去运算又进位了
其他的图运行都良好，今天突然间发现这个不进位了


(defun C:33 (/ SS S1 Q1 D Q2 Q3)
 (setq ss (entsel "\n选择多段线: "))
  (setq s1 (car ss));SS为entsel多线段
  (command "area" "e" s1)
  (setq q1 (getvar "area"))
  (setq d (getpoint "\n 请点取面积所放的位置："))
  (setq q2 (* (/ q1 6000) 9))
  (setq q1 (rtos q1 2 2))
  (setq q2 (rtos q2 2 3))
  (setq q3 (strcat "地块面积S=" q1 "平方米 合" q2 "亩"))
  (entmake (list '(0 . "TEXT")(cons 1 Q3)(cons 10 d)(cons 40 1)(cons 62 3)(cons 7 "宋体")))
)

llsheng_73 · 发表于 2022-8-3 08:46:00

_$ (setq real 35.2950)
35.295
_$ (rtos real 2 2)
"35.30"
_$ (setq real(- 35.2950 1e-5))
35.295
_$ real
35.295
_$ (rtos real 2 2)
"35.29"

copy

(defun myrtos2(real n / a)
  (setvar'dimzin 0)
  (rtos(+ real(/ 0.5(expt 10(1+ n))))2 n))

自贡黄明儒 · 发表于 2022-8-2 10:06:00

rtos是有一个变量控制的;;162.2 [功能] 保留小数位数(四舍五入)
;|(rtos 数 mode 小数位数)
mode
1  Scientific
2  Decimal
3  Engineering (feet and decimal inches)
4  Architectural (feet and fractional inches)
5  Fractional
|;
;;示例1 保留一位小数，四舍五入(HH:rtosr1 2.555 1)；"2.6"
;;示例2 取整数，四舍五入(read(HH:rtosr1 215.46 0))，返回215
;;示例3 十位数，四舍五入(* (read(HH:rtosr1 (/ 215.46 10) 0)) 10)，返回220
;;示例4 保留一位小数，四舍五入(read(HH:rtosr1 215.46 1))，返回215.5
(defun HH:rtosr1 (RealNum n / DIMZIN1 SHORTREAL1)
  (setq DimZin1 (getvar "DIMZIN"))
  (setvar "DIMZIN" 0)
  (setq ShortReal1 (rtos RealNum 2 n))
  (setvar "DIMZIN" DimZin1)
  ShortReal1
)