在autocad2002中能取消鼠标双击弹出的缺省属性框吗？

yingxy · 发表于 2004-9-17 00:29:00

我用lsp语句，可以把自己的函数加入到鼠标双击的事件中了，但是运行完自己的函数后，总是自动弹出原来缺省的属性框，不知道怎么取消，我只想运行自己的函数，不想再弹出缺省的属性对话框，请指教，谢谢！

masterlong · 发表于 2004-9-17 01:47:00

你应该是装了扩展工具后将双击属性开关打开了
dcprops off

yingxy · 发表于 2004-9-17 07:36:00

那我怎么关闭呢？扩展工具是需要的，肯定不能卸载的啊

meflying · 发表于 2004-9-17 08:21:00

这个应该跟et工具无关,关不掉的

雪山飞狐_lzh · 发表于 2004-9-17 09:00:00

把acdblclkedit.arx卸载掉

spring · 发表于 2004-9-17 10:09:00

厉害,这你也知道.
请问如何用lsp语句，可以把自己的函数加入到鼠标双击的事件中

masterlong · 发表于 2004-9-17 11:06:00

如果跟et有关，怎么关闭，我的帖子不是已经有了吗？
如果无关，那就在你的程序里加(arxunload "acdblclkedit.arx" nil)

masterlong · 发表于 2004-9-17 11:08:00

这是论坛里的一个范例文件，找不到原贴，拷贝在这里了
(defun jb:beginDoubleClick (reactorObject Listofsomething / point obj owner ownerobj command-list cmd gripset)
;;; added for error in 2004 - point returned from outside a
;;; paperspace viewport throws an error.
(if (vl-catch-all-error-p (vl-catch-all-apply 'trans (list (car Listofsomething) 0 1)))
(princ "PaperSpace")
(progn
(setq cmd "_.PROPERTIES" ; command default
point Listofsomething
obj (car (nentselp (trans (car point) 0 1)))
owner (car (cadddr (nentselp (trans (car point) 0 1))))
gripset (cadr (ssgetfirst))
doc (vlax-get (vlax-get-acad-object) "activedocument")
)
(if obj
(progn
; this statement will determine if the object
; clicked over is an insert or not
(cond
(owner (setq ownerobj (strcase (vlax-get (vlax-ename->vla-object owner) "objectname"))))
(T (setq ownerobj (strcase (vlax-get (vlax-ename->vla-object obj) "objectname"))))
)
;Now set up your commands for the appropriate object
; Object Command
;(cons "ACDBBLOCKREFERENCE" "_.REFEDIT ")
(setq command-list
(list (cons "ACDBBLOCKREFERENCE" "_.REFEDIT")
(cons "ACDBATTRIBUTE" "_.ATTEDIT")
(cons "ACDBMTEXT" "_.DDEDIT")
(cons "ACDBTEXT" "_.DDEDIT")
(cons "ACDBROTATEDDIMENSION" "_.DDEDIT")
(cons "ACDBALIGNEDDIMENSION" "_.DDEDIT")
(cons "ACDBORDINATEDIMENSION" "_.DDEDIT")
(cons "ACDBDIAMETRICDIMENSION" "_.DDEDIT")
(cons "ACDBRADIALDIMENSION" "_.DDEDIT")
(cons "ACDB2LINEANGULARDIMENSION" "_.DDEDIT")
(cons "ACDBMLINE" "_.MLEDIT")
(cons "ACDBATTRIBUTEDEFINITION" "_.DDEDIT")
(cons "ACDBHATCH" "_.HATCHEDIT")
(cons "ACDBRASTERIMAGE" "_.IMAGEADJUST")
(cons "AECDBWALL" "_.PROPERTIES")
(cons "AECDBDOOR" "_.PROPERTYDATAEDIT")
(cons "AECDBWINDOW" "_.PROPERTIES")
(cons "AECDBWINDOWASSEMBLY" "_.PROPERTIES")
(cons "AECDBCURTAINWALLLAYOUT" "_.PROPERTIES")
(cons "AECDBSPACE" "_.PROPERTYDATAEDIT")
(cons "AECDBSTAIR" "_.PROPERTIES")
(cons "AECDBRAILING" "_.PROPERTIES")
(cons "AECDBMVBLOCKREF" "_.PROPERTIES")
(cons "AECDBOPENING" "_.PROPERTIES")
(cons "AECDBCEILINGGRID" "_.PROPERTIES")
(cons "AECDBCOLUMNGRID" "_.PROPERTIES")
(cons "AECDBSLAB" "_.PROPERTIES")
(cons "AECSDBMEMBER" "_.PROPERTIES")
(cons "AECDBMASSELEM" "_.PROPERTIES")
(cons "AECDBROOF" "_.PROPERTIES")
(cons "AECDBROOFSLAB" "_.PROPERTIES")
(cons "AECDBCAMERA" "_.PROPERTIES")
(cons "AECDBSCHEDULETABLE" "_.PROPERTIES")
)
)
;;; get the command
(foreach x command-list
(if (= (car x) ownerobj) (setq cmd(cdr x)))
)
;;; make adjustment to command
(cond
((= cmd "_.REFEDIT") (setq cmd "_.refedit (princ (cdr (nentselp (trans(car point)0 1)))) "))
((= cmd "_.ATTEDIT") (setq cmd "_.attedit (princ obj) "))
((= cmd "_.EATTEDIT") (setq cmd "_.eattedit (princ obj) "))
(t (setq cmd(strcat cmd " ")))
)
(vla-sendcommand doc cmd)
);;progn
);;if
);;progn
);;if
(princ)
);;_ end of jb:beginDoubleClick _ ;;
;
;
;
(defun jboadDoublClickReactor (/)
;=;(if (/= (type jbDoubleClickReactor) 'VLR-MOUSE-REACTOR)
;=; (setq jbDoubleClickReactor
;=; (VLR-Mouse-Reactor nil '((:VLR-beginDoubleClick . jb:beginDoubleClick))) ;_ end of vlr-editor-reactor
;=; )
;=;)
(setq jbDoubleClickReactor
(VLR-Mouse-Reactor nil '((:VLR-beginDoubleClick . jb:beginDoubleClick))) ;_ end of vlr-editor-reactor
)
(if (not (vlr-added-p jbDoubleClickReactor)) (vlr-add jbDoubleClickReactor))
;;; Unload acdblclkedit.arx in favor of jb's Expanded Double Click editing!
(if (member "acdblclkedit.arx" (arx)) (arxunload "acdblclkedit.arx" nil))
(princ)
);;_ end of jboadDoublClickReactor _ ;;

(progn (jboadDoublClickReactor) (princ))

龙龙仔 · 发表于 2004-9-17 12:29:00

原贴
http://discussion.autodesk.com/thread.jspa?messageID=2095286

alin · 发表于 2004-9-17 19:05:00

这里还有一个范例，因为我没有什么用，不知你有没有用？复制代码

在autocad2002中能取消鼠标双击弹出的缺省属性框吗？

发表回复

精选推荐