[编程交流] 从字符串中删除某些内容

(setq str "[2017.03.06][2016.12.10]blueprint.dwg")
(strcat        (vl-string-right-trim
  " "
  (apply 'strcat
         (mapcar ''((x) (strcat (vl-princ-to-string x) " "))
                 (vl-remove-if 'vl-consp (read (strcat "(" (vl-string-translate "[]" "()" str) ")")))
                 )
         )
  )
".dwg"
)

; _$ (foo "[2017.03.06][2016.12.10]Blueprint.dwg") -> "Blueprint.dwg"
; _$ (foo "[2017.03.06][2016.12.10]This is a test.dwg") -> "This is a test.dwg"
(defun foo ( s )
 (cond 
   ( (wcmatch s  "`[####`.##`.##`]`[####`.##`.##`]*`.dwg")
     (substr s 25)
   )
 )
)

(defun foo ( str / rgx )
   (if (setq rgx (vlax-get-or-create-object "vbscript.regexp"))
       (progn
           (vlax-put-property rgx 'global actrue)
           (vlax-put-property rgx 'pattern "\\[\\d{4}\\.\\d{2}\\.\\d{2}\\]")
           (setq str (vlax-invoke rgx 'replace str ""))
           (vlax-release-object rgx)
           str
       )
   )
)

_$ (foo "[2017.03.06]Blueprint.dwg")
"Blueprint.dwg"
_$ (foo "[2017.03.06][2016.12.10]Blueprint.dwg")
"Blueprint.dwg"
_$ (foo "[2017.03.06][2016.12.10][2016.12.10]Blueprint.dwg")
"Blueprint.dwg"

; _$ (foo "[2013.12.10]Blueprint.dwg") -> "Blueprint.dwg"
; _$ (foo "[2015.08.10][2016.12.10]This is a test.dwg") -> "This is a test.dwg"
; _$ (foo "[2012.02.13][1991.08.10][2016.12.10]And Another test.dwg") -> "And Another test.dwg"
(defun foo ( s )
 (cond 
   ( (wcmatch s  "`[####`.##`.##`]*`.dwg") 
     (while (wcmatch s  "`[####`.##`.##`]*`.dwg")
       (setq s (substr s 13))
     )
   )
 )
)