[编程交流] 如何将所有点更改为

(defun C:ptr ()
(setq wide (getdist "\nEnter Rectangle X Dimension ? :")
(setq high (getdist "\nEnter Rectangle Y Dimension ? :")
(setq ptc (getpoint "\nPick Center of Rectangle:")
hwide (/ wide 2.0)
hhigh (/ high 2.0)
ptll (list (- (car ptc) hwide) (- (cadr ptc) hhigh))
ptur (list (+ (car ptll) wide) (+ (cadr ptll) high))
)
(setvar "plinewid" 0.0)
(command ".PLINE" ptll "W" "0" "0" ".X" ptur ".Y" ptll ptur ".X" ptll ".Y" ptur "C")
)
(prin1)

(defun c:Test (/ w h p)
 (if (and (setq w (getdist "\n Specify Rectangle X Dimension :"))
          (setq h (getdist "\n Specify Rectangle Y Dimension :"))
          (setq p (getpoint "\n Pick Center Point of Rectangle:"))
     )
   (command "_.rectang" "_w" 0.0 "_non" (setq 1p (polar (polar p (* pi 0.5) (/ h 2.)) pi (/ w 2.))) "_non"
            (polar (polar 1p 0. w) (* pi 1.5) h)
   )
 )
 (princ)
)

(defun c:Test (/ w h p s i 1p 2p 3p 4p)
 ;;         Tharwat 10.12.2014                ;;
 ;; Draw rectangles using the center         ;;
 ;;         of selected points                 ;;
 (if (and (setq w (getdist "\n Specify Rectangle X Dimension :"))
          (setq h (getdist "\n Specify Rectangle Y Dimension :"))
          (princ "\n Select Point objects ...")
          (setq s (ssget '((0 . "POINT"))))
     )
   (repeat (setq i (sslength s))
     (setq p  (cdr (assoc 10 (entget (ssname s (setq i (1- i))))))
           1p (polar (polar p (* pi 0.5) (/ h 2.)) pi (/ w 2.))
           2p (polar 1p 0. w)
           3p (polar 2p (* pi 1.5) h)
           4p (polar 3p pi w)
     )
     (entmakex
       (append (list '(0 . "LWPOLYLINE")
                     '(100 . "AcDbEntity")
                     '(100
                       .
                       "AcDbPolyline"
                      )
                     '(90 . 4)
                     '(70 . 1)
               )
               (mapcar '(lambda (q) (cons 10 q)) (list 1p 2p 3p 4p))
       )
     )
   )
 )
 (princ)
)

(setq s (ssget '((0 . "POINT"))))

(setq s (ssget '((0 . "POINT,CIRCLE"))))