一个拖动函数

meflying · 发表于 2004-4-15 09:59:00

想到ET里有个拖动的函数,我也做了一个,效果比用MOVE应该好多了:;函数：(Drag ss pt)
;功能：实现拖动效果
;参数：ss——需要实现拖动效果的对象选择集
; pt——拖动过程鼠标移动起点
;返回：左键拖动过程鼠标移动终点，否则返回nil（根据拖动过程的起点和终点就可以做需要做的事情了）

copy


(defun Drag (ss pt / blk ent ents m gr rVal mc-make-unname-block)
   (defun mc-make-unname-block (pt ss / count entlist ent blk)
       (entmake (list '(0 . "BLOCK")
         '(2 . "*U")
         '(70 . 1)
         (cons 10 pt)
           )
       )
       (setq count 0)
       (repeat (sslength ss)
           (setq entlist (entget (setq ent (ssname ss count))))
           (setq count (1+ count))
           (entmake entlist)
       )
       (setq count 0)
       (repeat (sslength ss)
           (setq ent (ssname ss count))
           (setq count (1+ count))
       )
       (setq blk (entmake '((0 . "ENDBLK"))))
   )
   (if (setq blk (mc-make-unname-block pt ss))
       (progn
           (entmake (list (cons 0 "INSERT")
             (cons 2 blk)
             (cons 10 pt)
               )
           )
           (setq ent (entlast))
       )
   )
   (if ent
       (progn
           (setq ents (entget ent))
           (setq m   t
         rVal nil
           )
           (while m
  (setq gr (grread 2 4))
  (cond
     ((= (car gr) 5)
       (setq ents (subst (cons 10 (cadr gr)) (assoc 10 ents) ents))
       (entmod ents)
     )
     ((= (car gr) 3)
       (setq m nil)
       (setq rVal (cadr gr))
       (entdel ent)
       (command "_.purge" "b" blk "n")
     )
     (t (setq m nil) (entdel ent)(command "_.purge" "b" blk "n"))
  )
           )
       )
   )
   rVal
)

龙龙仔 · 发表于 2004-4-15 11:50:00

;;建議:
;;1.無名BLOCK不用清除(因AUTOCAD會自動清除)
;;2.要是能改得像MOVE那樣的效果會更直覺
;;3.無名塊的程序對POLYLINE及屬性會有問題

meflying · 发表于 2004-4-15 12:26:00

对于3,龙版有什么好办法?

无痕 · 发表于 2004-4-15 13:49:00

比move好在哪里？我看不出来
move还可以捕捉，而且定义为块再删除，过程计算复杂，如果选中的实体很多，会很慢。
建议用矩阵变换的办法最直接。

meflying · 发表于 2004-4-15 14:05:00

你用move做一个(注意,是使用它来做拖动效果,并不是单独使用MOVE命令)就知道了,在拖动时会很闪,而用我这个程序则会变的十分平滑...
计算过程应该相当简单吧,仅仅是把块的插入点改为当前鼠标所在点而已...如果多了,即使CAD内部的拖动也一样慢...
如果用距阵计算,那才应该叫计算复杂,要对每个对象,每个相关点都要计算,碰到椭圆等还得单独考虑,这样我想肯定慢...

BDYCAD · 发表于 2004-4-15 17:22:00

這個我一直在尋找. 效果很好. 這個我一直在尋找. 效果很好. 我以前的做法是做成一個把選到的對象在LISP中以基點方式使用指令復制到剪切板. 然后粘貼出來. 做法可說比你的簡單. 但是不是生成無名塊的原因吧. 到要關系圖里要清理塊. 不知飛歌這個是不是改善了很多. 下載試試.

无痕 · 发表于 2004-4-15 19:23:00

我认为矩阵变换是cad的基本位移旋转缩放镜向的基础，如move，虽然命令简单，但是也是根据矩阵来进行运算的，只不过这个运算已经已经固化到cad基本程序里面了，因此并不能说程序步骤简单运算就一定简单。包子，我觉得你用的方法也很好
一个简单的测试：
写一个文字“测试程序”。用array原地复制20*20个。就知道move和drag的区别了。
顺便说一句。用dragp1，dragp2可条件拖曳时的采样率，越小显示越快。
结论：drag确实平滑，将以上两个系统变量调整到最高，也无法达到drag的平滑效果。
但是不建议在选择多个物体时候使用，因为那会很慢。