在a的两端输入一个油炸圈饼

tmelancon · 发表于 2022-7-5 17:11:26

我真的需要一个lisp来找到线的端点，然后从这些端点偏移[0.25]，并在一行或多行的端点插入一个实心的“甜甜圈”。我有我们目前正在使用的甜甜圈lisp，以及我在网上找到的另一个lisp，它非常接近我所需要的。请参阅下面的lisp和图片，了解当前代码的作用以及我正在寻找的内容。提前感谢论坛中的每一个人，非常感谢你们的帮助！

这是我使用的Solid Donut命令。我们称之为bb's。

这是我发现的有点接近的lisp。KENT1COOPER通过AutoDesk论坛提供：

当前例行程序：

登录/注册后可看大图

新的常规：（我想尝试并让它做什么）

登录/注册后可看大图

Lee Mac · 发表于 2022-7-5 17:20:10

尝试以下操作：

copy

(defun c:dlines ( / e i p q s )
   (if (setq s (ssget '((0 . "LINE"))))
       (repeat (setq i (sslength s))
           (setq e (entget (ssname s (setq i (1- i))))
                 p (cdr (assoc 10 e))
                 q (cdr (assoc 11 e))
           )
           (LM:donut (polar p (angle p q) 0.25) 0.0 0.0335)
           (LM:donut (polar q (angle q p) 0.25) 0.0 0.0335)
       )
   )
   (princ)
)
;; Donut  -  Lee Mac
;; cen - [lst] Donut center
;; rd1 - [num] Inside radius
;; rd2 - [num] Outside radius
(defun LM:donut ( cen rd1 rd2 / ocs thk )
   (setq thk (abs (- rd2 rd1))
         ocs (trans '(0 0 1) 1 0 t)
   )
   (entmakex
       (list
          '(000 . "LWPOLYLINE")
          '(100 . "AcDbEntity")
          '(100 . "AcDbPolyline")
          '(090 . 2)
          '(070 . 1)
           (cons 43 thk)
           (cons 10 (polar (trans cen 0 ocs) pi (+ rd1 (/ thk 2.0))))
          '(042 . 1)
           (cons 10 (polar (trans cen 0 ocs) 0  (+ rd1 (/ thk 2.0))))
          '(042 . 1)
           (cons 210 ocs)
       )
   )
)

tmelancon · 发表于 2022-7-5 17:28:31

再一次，又是一件精彩的作品。非常感谢李。祝福！工作得很有魅力！

Lee Mac · 发表于 2022-7-5 17:33:13

不客气

BIGAL · 发表于 2022-7-5 17:37:09

你也可以用样条线通过顶点计算出新的圆环点。李？

Lee Mac · 发表于 2022-7-5 17:45:38

当然，比如：

copy

(defun c:dlines ( / e i l s )
   (if (setq s (ssget '((0 . "LINE,LWPOLYLINE"))))
       (repeat (setq i (sslength s))
           (setq e (entget (ssname s (setq i (1- i)))))
           (if (= "LINE" (cdr (assoc 0 e)))
               (setq l (list (cdr (assoc 10 e)) (cdr (assoc 11 e))))
               (setq l (mapcar 'cdr (vl-remove-if-not '(lambda ( x ) (= 10 (car x))) e)))
           )
           (while (cadr l)
               (LM:donut (polar (car  l) (angle (car  l) (cadr l)) 0.25) 0.0 0.0335)
               (LM:donut (polar (cadr l) (angle (cadr l) (car  l)) 0.25) 0.0 0.0335)
               (setq l (cdr l))
           )
       )
   )
   (princ)
)
;; Donut  -  Lee Mac
;; cen - [lst] Donut center
;; rd1 - [num] Inside radius
;; rd2 - [num] Outside radius
(defun LM:donut ( cen rd1 rd2 / ocs thk )
   (setq thk (abs (- rd2 rd1))
         ocs (trans '(0 0 1) 1 0 t)
   )
   (entmakex
       (list
          '(000 . "LWPOLYLINE")
          '(100 . "AcDbEntity")
          '(100 . "AcDbPolyline")
          '(090 . 2)
          '(070 . 1)
           (cons 43 thk)
           (cons 10 (polar (trans cen 0 ocs) pi (+ rd1 (/ thk 2.0))))
          '(042 . 1)
           (cons 10 (polar (trans cen 0 ocs) 0  (+ rd1 (/ thk 2.0))))
          '(042 . 1)
           (cons 210 ocs)
       )
   )
)