已知路径请问如何用LISP语句打开？

jxb8888 · 发表于 2004-9-5 20:13:00

已知路径，例： c:\\abc\\wh1023.dwg
请问如何用LISP语句打开？

ZZXXQQ · 发表于 2004-9-5 23:59:00

(command "open" "c:/abc/wh1023")

龙龙仔 · 发表于 2004-9-6 12:25:00

;;--------------------------------------------------------------
(vl-load-com)
;;;In MDI mode
(vla-open (vla-get-documents (vlax-get-acad-object))
   "yourdrawing"
)
;;;In SDI mode
(vla-open (vla-get-activedocument (vlax-get-acad-object))
   "yourdrawing"
)
;;--------------------------------------------------------------
(vla-activate
   (vla-open (vla-get-documents (vlax-get-acad-object)))
)
;;--------------------------------------------------------------
;;; opens and activates a file as Read-Only
(defun OPENRO (FNA)
   (vla-activate
   (vla-open (vla-get-documents (vlax-get-acad-object))
   FNA
   :vlax-true
   )
   )
)
;;--------------------------------------------------------------
(defun C:OPENDWG (/ NAME)
   (vl-load-com)
   (setq NAME (getfiled "Select File" (getvar "dwgprefix") "dwg" 16))
   (if (= 0 (getvar "SDI"))
   (command "_.VBASTMT"
   (strcat "AcadApplication.Documents.Open \"" NAME "\"")
   )
   (command "_.VBASTMT"
   (strcat "AcadApplication.activedocument.Open \"" NAME "\"")
   )
   )
)
;;=============================================================
(command "fileopen" "y" "路径名")
;;=============================================================
(defun OPENFILE (DWGFILE / ACAD ACADDOC OPENDOC)
   (vl-load-com)
   (setq ACAD (vlax-get-acad-object))
   (setq ACADDOC (vlax-get-property ACAD 'DOCUMENTS))
   (setq OPENDOC (vlax-invoke-method ACADDOC 'open DWGFILE))
   (if (/= OPENDOC NIL)
   (vlax-invoke-method OPENDOC 'ACTIVATE)
   (prompt "\nFailed to open drawing file.")
   )
)
(defun c:test ()
(command "sdi" "1")
(command "new" "y" "C:\\Program Files\\AutoCAD 2002\\Template\\acad.dwt")
(command "sdi" "0")
)

青青20 · 发表于 2004-9-6 20:01:00

在程序中这样有些问题(command "open"...)
刚打开CAD时能行,如果有图的话不行(如在菜单下调用lisp)

已知路径请问如何用LISP语句打开？

发表回复

精选推荐