为什么产生的不是带属性的块？

fqlh · 发表于 2004-6-22 16:35:00

采用以下lisp程序产生一匿名属性块,然后用"battman"命令后，选择刚刚产生的匿名属性块，却提示说“选定的块没有属性”。这是为什么？是程序哪个环节有问题，请指出。
(defun c:test()
   (setq pt-insert '(0 0 0))
   (setq pt (append '((0 . "block")(2 . "*U")(70 . 1)) (list (cons 10 pt-insert))))
   (entmake pt)
   (setq pt1 (polar pt-insert (/ pi 2) 0.8))
   (setq pt1 (polar pt1 0 -2))
   (setq pt2 (polar pt1 0 4))
   (setq pt (append '((0 . "LINE")) (list (cons 10 pt1))(list (cons 11 pt2))))
   (entmake pt)
   (setq pt1 (polar pt-insert (/ pi 2) 0.8))
   (setq pt2 (polar pt1 (/ pi 2) 3))
   (setq pt (append '((0 . "LINE")) (list (cons 10 pt1))(list (cons 11 pt2))))
   (entmake pt)
   (setq pt1 (polar pt-insert (/ pi 2) 6.3))
   (setq pt (append '((0 . "CIRCLE")(40 . 2.5)) (list (cons 10 pt1))))
   (entmake pt)
   (setq pt (polar pt-insert (/ pi 2) 6.3))
   (setq lst (append '((0 . "ATTDEF")
   (100 . "AcDbEntity")
   (67 . 0)
   (100 . "AcDbText")
   (1 . "0")
   (50 . 0.0)
   (40 . 3)
   (41 . 0.8)
   (51 . 0.0)
   (7 . "STANDARD")
   (71 . 0)
   (72 . 1)
   (210 0.0 0.0 1.0)
   (100 . "AcDbAttributeDefinition")
   (3 . "基准名称")
   (2 . "1")
   (70 . 0)
   (73 . 0)
   (74 . 2)
   )
   (list (cons 10 pt))
   (list (cons 11 pt))
   )
);setq lst
   (entmake lst)
   (setq blkn (entmake '((0 . "ENDBLK"))))
   (setq lst '((0 . "INSERT")
   (100 . "AcDbEntity")
   (67 . 0)
   (100 . "AcDbBlockReference")
   (66 . 1)
   (41 . 1.0)
   (42 . 1.0)
   (43 . 1.0)
   (50 . 0.0)
   (70 . 0)
   (71 . 0)
   (44 . 0.0)
   (45 . 0.0)
   (210 0.0 0.0 1.0)
   )
);setq lst
   (setq lst (append lst (list (cons 2 blkn)) (list (cons 10 pt-insert)))) ;结束义
   (entmake lst)
   (setq pt (polar pt-insert (/ pi 2) 6.3))
   (setq lst (append '((0 . "ATTRIB")
   (5 . "26")
   (100 . "AcDbEntity")
   (67 . 0)
   (100 . "AcDbText")
   (50 . 0.0)
   (40 . 3.0)
   (41 . 0.8)
   (51 . 0.0)
   (7 . "STANDARD")
   (71 . 0)
   (72 . 1)
   (210 0.0 0.0 1.0)
   (100 . "AcDbAttribute")
   (2 . "1")
   (70 . 0)
   (73 . 0)
   (74 . 2)
   )
   (list (cons 10 pt))
   (list (cons 11 pt))
   (list (cons 1 "A"))
   )
);setq lst
   (entmake lst)
   (entmake '((0 . "SEQEND")))
)

alin · 发表于 2004-6-22 19:48:00

大概无名块不能含有属性吧

meflying · 发表于 2004-6-22 20:52:00

摘自帮助文件。。。属性和匿名组合一下(cons 70 3)即可
70 块类型标志（按位编码值，可以组合使用）：
0 = 表示不应用下列任何标志
1 = 由图案填充、关联标注、其他内部操作或应用程序生成的匿名块
2 = 块具有非固定属性定义（如果块具有任何固定属性定义或根本没有属性定义，则不设置此位）
4 = 块是外部参照 (xref)
8 = 块是外部参照覆盖
16 = 块依赖外部参照
32 = 块是融入的外部参照，或者依赖外部参照（输入时被忽略）
64 = 定义是被引用的外部参照（输入时
被忽略）

alin · 发表于 2004-6-23 15:14:00

meflying:
Could you please specify in which section of the code we should change to (cons 70 3)? It still doesn't work :)

龙龙仔 · 发表于 2004-6-23 15:34:00

呵呵!
http://discussion.autodesk.com/thread.jspa?threadID=340742

雪山飞狐_lzh · 发表于 2004-6-23 15:45:00

哈哈，绕一圈又回来了

meflying · 发表于 2004-6-23 15:52:00

...((0 . "block")(2 . "*U")(70 . 1)) ... 建立block时，如上面。。。就改了这么一个地方，就可以了：PS：龙大侠真幽默，带我们畅游网络啊

copy


(defun c:test()
   (setq pt-insert '(0 0 0))
   (setq pt (append '((0 . "block")(2 . "*U")(70 . 3)) (list (cons 10 pt-insert))))
   (entmake pt)
   (setq pt1 (polar pt-insert (/ pi 2) 0.8))
   (setq pt1 (polar pt1 0 -2))
   (setq pt2 (polar pt1 0 4))
   (setq pt (append '((0 . "LINE")) (list (cons 10 pt1))(list (cons 11 pt2))))
   (entmake pt)
   (setq pt1 (polar pt-insert (/ pi 2) 0.8))
   (setq pt2 (polar pt1 (/ pi 2) 3))
   (setq pt (append '((0 . "LINE")) (list (cons 10 pt1))(list (cons 11 pt2))))
   (entmake pt)
   (setq pt1 (polar pt-insert (/ pi 2) 6.3))
   (setq pt (append '((0 . "CIRCLE")(40 . 2.5)) (list (cons 10 pt1))))
   (entmake pt)
   (setq pt (polar pt-insert (/ pi 2) 6.3))
   (setq lst (append '((0 . "ATTDEF")
               (100 . "AcDbEntity")
               (67 . 0)
               (100 . "AcDbText")
               (1 . "0")
               (50 . 0.0)
               (40 . 3)
               (41 . 0.8)
               (51 . 0.0)
               (7 . "STANDARD")
               (71 . 0)
               (72 . 1)
               (210 0.0 0.0 1.0)
               (100 . "AcDbAttributeDefinition")
               (3 . "基准名称")
               (2 . "1")
               (70 . 0)
               (73 . 0)
               (74 . 2)
               )
           (list (cons 10 pt))
           (list (cons 11 pt))
           )
  );setq lst
   (entmake lst)
   (setq blkn (entmake '((0 . "ENDBLK"))))
   (setq lst '((0 . "INSERT")
             (100 . "AcDbEntity")
             (67 . 0)
             (100 . "AcDbBlockReference")
             (66 . 1)
             (41 . 1.0)
             (42 . 1.0)
             (43 . 1.0)
             (50 . 0.0)
             (70 . 0)
             (71 . 0)
             (44 . 0.0)
             (45 . 0.0)
             (210 0.0 0.0 1.0)
             )
  );setq lst
   (setq lst (append lst (list (cons 2 blkn)) (list (cons 10 pt-insert)))) ;结束义 
                   (entmake lst)
   (setq pt (polar pt-insert (/ pi 2) 6.3))
   (setq lst (append '((0 . "ATTRIB")
               (5 . "26")
               (100 . "AcDbEntity")
               (67 . 0)
               (100 . "AcDbText")
               (50 . 0.0)
               (40 . 3.0)
               (41 . 0.8)
               (51 . 0.0)
               (7 . "STANDARD")
               (71 . 0)
               (72 . 1)
               (210 0.0 0.0 1.0)
               (100 . "AcDbAttribute")
               (2 . "1")
               (70 . 0)
               (73 . 0)
               (74 . 2)
               )
           (list (cons 10 pt))
           (list (cons 11 pt))
           (list (cons 1 "A"))
           )
  );setq lst
   (entmake lst)
   (entmake '((0 . "SEQEND")))
)

龙龙仔 · 发表于 2004-6-23 16:27:00

我看到alin在提问就回覆一下 8-)
顺便打打广告!Alin:
I think that is you want
乐筑天下就有资料比这更强
龙龙仔
"alin" 在邮件
news:32570799.1087953402985.JavaMail.jive@jiveforum2.autodesk.com 中撰写...
> Can anonymous block has attributes?

alin · 发表于 2004-6-23 19:31:00

龙斑竹果然神了，呵呵

为什么产生的不是带属性的块？

发表回复

精选推荐

浏览过的版块