求区域面积！！！

梁旭武 · 发表于 2004-5-14 14:30:00

是我编的小程序：谢谢指导！！(defun c:tt()
(setq a(getpoint"\n点区域"))
(command "boundary" a "" "Y")
(setq b(entlast))
(command "area" "O" b)
(setq c (getvar "AREA"))
(command "text" a 3 0 (rtos c))
(command "ERASE" b "")
)

wb0815 · 发表于 2004-5-14 14:47:00

不错挺使用的

redearth · 发表于 2004-5-14 18:57:00

region也能行吗？？

BDYCAD · 发表于 2004-5-15 08:21:00

我在書上找到一個, 也是蠻不錯的哦. 給大火參考參考呵呵(defun c:lsp_45()
   (setvar "cmdecho" 0)
   (setq pt (getpoint "\n選取點:"))
   (while pt
   (setvar "cecolor" "1")
   (command "bpoly" pt "")
   (setq en (entlast))
   (if en
   (progn
(command "area" "o" en)
(setq aa (getvar "area"))
(redraw en 3)
(alert (strcat "面積=" (rtos aa 2)))))
   (entdel en)
   (setvar "cecolor" "bylayer")
   (setq pt (getpoint "\n選取點:"))
   )
   (princ))

lzy9788 · 发表于 2004-5-15 23:07:00

我也编了一个，请指教:
(defun c:area2 ()
(setvar "cmdecho" 0)
(command "_.undo" "be")
(setq pt (getpoint "\n面积自动计算并标注 VER 1.0---by Rokin！\n请点取要标注的范围内一点:"))
(command "-boundary" pt "")
(command "area" "o" (entlast))
(command "erase" (entlast) "")
(setq area (getvar "area"))
(command "style" "幼圆" "幼圆" "" "" "" "" "")
(command "text" "j" "c" pt "250" "0" (strcat (rtos (/ area 1000000) 2 3) "M"))
(princ (strcat "\n该范围的面积为A=" (rtos (/ area 1000000) 2 3) "M" (strcat "(" (rtos area 2 0) "mm)。") "\n***面积自动计算并标注--ver 1.0***(2004年2月 by Rokin)!\n"))
(command "_.undo" "e")
(setvar "cmdecho" 1)
(princ))

无痕 · 发表于 2004-5-16 00:26:00

有点bug,当点中实体或非封闭区域，后面就不正常了。修改一下:

copy


(defun c:aaa(/ oc occ enl pt en)
   (mapcar 'set '(oc occ) (mapcar 'getvar '("cmdecho" "cecolor")))
   (mapcar 'setvar '("cmdecho" "cecolor") '(0 "1"))
   (setq enl (entlast))
   (while (setq pt (getpoint "\n选点:"))
       (if (and (vl-cmdf "bpoly" pt "")(not(equal enl (setq en (entlast)))))
               (progn (command "area" "o" en)
                             (alert (strcat "面积=" (rtos (getvar "area") 2)))
                             (entdel en)
               )
       )
   )
   (mapcar 'setvar '("cmdecho" "cecolor") (list oc occ))
   (princ)
)

求区域面积！！！

发表回复

精选推荐