[求助]这是一个对齐标注的程序，请帮忙修改一下

                                        ;修改<35%代码,请标明aeo
                                        ;有更好的,希望贴出来大家分享
(defun c:TD (/            ang           e          en         j        len    olderr os
             pt1    pt2           pt3          pt4         ss        aeoerr trim-dim
             dxf
            )
  (defun dxf (a b) (cdr (assoc a b)))
  (defun aeoerr        (msg)
    (command "_.undo" "end" ^c)
    (setvar "osmode" os)
    (setq *error* olderr)
  )
  (defun trim-dim (pt1 pt2 ss / ent entl i np13 np14 p10 p13 p14 ptt)
                                        ; 这一; 段改自"程序（函数）库"
    (setvar "osmode" 0)
    (setq pt1 (trans pt1 1 0)
          pt2 (trans pt2 1 0)
          i   0
    )
    (repeat (sslength ss)
      (setq ent         (ssname ss i)
            entl (entget ent)
            p10         (cdr (assoc 10 entl))
            p13         (cdr (assoc 13 entl))
            p14         (cdr (assoc 14 entl))
            ptt         (cdr (assoc 11 entl))
            i         (1+ i)
            np14 (inters
                   pt1 pt2 p14 p10 nil)
      )
      (if (not (member '(100 . "AcDbRotatedDimension") entl))
        (setq np13 (polar np14 (angle p14 p13) (distance p14 p13)))
        (setq np13 (inters
                     pt1
                     pt2
                     p13
                     (polar p13 (angle p14 p10) 100)
                     nil
                   )
        )
      )
      (setq entl (subst
                   (cons 13 np13)
                   (assoc 13 entl)
                   entl
                 )
            entl (subst
                   (cons 14 np14)
                   (assoc 14 entl)
                   entl
                 )
      )
      (entmod entl)
    )
  )
;;;;;;;
  (setq        os        (getvar "osmode")
        olderr        *error*
        *error*        aeoerr
  )
  (setvar "osmode" 0)
  (command "undo" "group")
  (prompt "\nby aeo")
  (prompt "\n不要修改的标注不要选在里面")
  (if (setq ss (ssget '((0 . "DIMENSION"))))
    (progn
      (setq en (entget (ssname ss 0)))
      (if (member '(100 . "AcDbRotatedDimension") en)
        (setq ang (dxf 50 en))
        (setq ang (angle (dxf 13 en) (dxf 14 en)))
      )
    )
  )
  (setvar "osmode" 15359)
  (if (and
        ang
        (setq pt1 (getpoint "\n标注线位置(回车不改):"))
      )
    (progn
      (setq pt2        (polar pt1 ang 1000)
            j        0
            len        (sslength ss)
      )
      (setvar "osmode" 0)
      (while (< j len)
        (setq e          (ssname ss j)
              en  (entget (ssname ss j))
              pt3 (dxf 10 en)
              pt4 (inters
                    pt1
                    pt2
                    pt3
                    (polar pt3 (+ ang (* 0.5 pi)) 100)
                    nil
                  )
              j          (1+ j)
        )        
        (command "move" e "" pt3 pt4)
      )
    )
  )
  (setvar "osmode" 15359)
  (if (and
        ang
        (setq pt1 (getpoint "\n引出线位置(回车不改):"))
      )
    (trim-dim pt1 (polar pt1 ang 100) ss)
  )
  (setvar "osmode" os)
  (setq *error* olderr)
  (command "_.undo" "end")
  (princ)
)